Як швидко роздрукувати всі файли в Zip Вкладене повідомлення електронної пошти Outlook

Багато користувачів сподіваються надрукувати всі файли, стиснуті в zip вкладене повідомлення електронної пошти Outlook без проблемного збереження та розпаковування zip вкладення. Отже, ця стаття запропонує набагато ефективніші засоби для її реалізації.

Коли ви хочете надрукувати файл zip вкладеного файлу, ви можете звикнути наносити на нього і натискати кнопку «Швидкий друк» на стрічці. Однак цим способом Outlook все одно попросить вас зберегти та вимкнутиzip це по-перше. Якщо ви хочете уникнути цих надокучливих кроків, ви можете використовувати наступний код VBA.

Роздрукувати всі файли в a Zip Вкладення електронного листа

1. Для початку сtart програми Outlook.
2. Потім отримайте доступ до редактора Outlook VBA, виконавши кроки, показані в статті - “Як запустити код VBA у своєму Outlook".
3. Далі ви можете відкрити проект “ThisOutlookSession” або невикористаний модуль.
4. Згодом скопіюйте та вставте код VBA нижче.

Dim objShell As Object
Dim objFileSystem As Object

Sub PrintAllFilesInZipAttachment ()
    Dim objAttachmentSelection As Outlook.AttachmentSelection
    Dim objAttachment, objTempAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim strSavingPath As String
    Dim objTempMail As Outlook.MailItem
    Dim strFileName As String
 
    'Get selected attachment
    Set objAttachmentSelection = Outlook.Application.ActiveExplorer.AttachmentSelection
    Set objAttachment = objAttachmentSelection.Item(1)

    If Right(LCase(objAttachment.filename), 3) = "zip" Then
 
       'Save & Unzip the zip attachment
       Set objShell = CreateObject("Shell.Application")
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Unzip" & Format(Now, "yyyymmddhhmmss")
       MkDir (strTempFolder)
 
       strSavingPath = strTempFolder & "\" & objAttachment.filename
       objAttachment.SaveAsFile (strSavingPath)
       objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strSavingPath)).Items
  
       'Attach Unzipped files to a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       strFileName = Dir(strTempFolder & "\")
 
       While Len(strFileName) > 0
             objTempMail.Attachments.Add (strTempFolder & "\" & strFileName)
             strFileName = Dir()
       Wend
 
       'Print all attachments of the temp email
       Call PrintFiles(objTempMail)
 
       objTempMail.Close olDiscard
 
       objFileSystem.DeleteFolder (strTempFolder)
    End If
End Sub

Sub PrintFiles(ByVal objMail As Outlook.MailItem)
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder, strFilePath As String
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
 
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\TEMP" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    'Print all attachments
    For Each objAttachment In objMail.Attachments
        If Right(LCase(objAttachment.filename), 3) <> "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile (strFilePath)
 
           Set objShell = CreateObject("Shell.Application")
           Set objTempFolder = objShell.NameSpace(0)
           Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
           objTempFolderItem.InvokeVerbEx ("print")
        End If
    Next
 
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Після цього закрийте поточне вікно редактора VBA.
6. Пізніше перейдіть до Параметри Outlook, щоб додати новий макрос на панель швидкого доступу.
7. Нарешті, ви можете зробити знімок:

• Спочатку виберіть a zip вкладення електронного листа.
• Потім клацніть макрос на панелі швидкого доступу.

8. Файли відразу стискаються у вибраному zip вкладення буде надруковано.

Резервне копіювання файлів даних Outlook

Можливо, ви виявили, що Outlook схильний до корупції. Як тільки Outlook буде пошкоджено, ваші дані Outlook будуть lost. Отже, важливо регулярно робити резервні копії файлів даних Outlook, щоб можна було легко отримувати дані Outlook за допомогою резервних копій. Але, якщо ви виявите, що резервна копія є кілька тижнів і неефективна, вам не залишається нічого іншого, як повернутися до надійного та досвідченого Відновлення PST інструмент, такий як DataNumen Outlook Repair.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі пошкоджений mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com