Belirli Bir E-postanın Yanıtını Beklenen Süre İçinde Almazsa Bildirim Nasıl Alınır?

Bu makale, belirli bir e-postanın yanıtını belirli bir süre içinde almadığınızda, Outlook'un size bir bildirim e-postası gönderip göndermemenizi otomatik olarak sormasını sağlamak için VBA'yı kullanarak hızlı bir numara öğretecektir.

Bazen, hayati derecede önemli e-postalar için, yanıtlarını kesinlikle dört gözle bekleyeceksiniz. Başka bir deyişle, alıcının size mümkün olan en kısa sürede yanıt vereceğini ummalısınız. Aksi takdirde, yanıtı beklediğiniz süre içinde henüz almadığınız sürece, alıcıya tekrar bir takip bildirim e-postası gönderirsiniz. Bu nedenle, bu gereksinime yanıt olarak, burada Outlook'un böyle bir durumda sizi otomatik olarak uyarmasını ve yönlendirmesini sağlamak için VBA'yı kullanan bir yöntem tanıtacağız. Ayrıntılı adımları ve kodları almak için okumaya devam edin.

Belirli Bir E-postanın Yanıtını Beklenen Süre İçinde Almazsa Bildirim Alın

1. En başta, start Outlook'unuz.
2. Ardından, belirli e-posta için belirli bir hatırlatma zamanı ayarlamanız gerekir.

• İlk olarak, belirli bir e-postaya sağ tıklayın.
• Ardından “Takip Et” > “Hatırlatıcı Ekle”yi seçin.
• İletişim kutusunda, yanıtını almak istediğiniz belirli süre ile aynı anımsatıcı süresini ayarlayabilirsiniz.

3. Bundan sonra, Outlook VBA düzenleyicisine erişmek için “Alt + F11” tuşlarına basın.
4. Ardından, yeni pencerede “ThisOutlookSession” projesini açın ve aşağıdaki kodları içine kopyalayın.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Daha sonra bu kodu imzalayın.
6. Daha sonra dijital olarak imzalanmış makrolara izin vermek için Outlook makro ayarını değiştirin.
7. Sonunda restarYeni makroyu etkinleştirmek için Outlook. Bundan sonra, Outlook aşağıdaki gibi çalışacaktır:

• Belirli bir e-postanın yanıtını hatırlatıcısı açılmadan önce aldıysanız, Outlook bayrağı otomatik olarak silecek ve hatırlatıcıyı devre dışı bırakacaktır.
• Hatırlatıcı etkinleştiğinde yanıtı almadıysanız, Outlook size bir takip bildirimi e-postası gönderip göndermemenizi ister. “Evet”i seçerseniz, e-posta gönderilecektir. “Hayır”ı seçerseniz, bilgi istemi bir anda kaybolacaktır.

Rahatsız Edici Outlook Sorunlarını Çözün

Outlook hataya açık olduğundan, önlemek için Outlook bozulması, yalnızca gelen kutusu aracı Scanpst.exe'ye güvenmemeniz daha iyi olur. Gibi başka bir güçlü ve saygın onarım aracı hazırlamalısınız. DataNumen Outlook Repair, Scanpst.exe'nin çözemediği can sıkıcı sorunları ortadan kaldırabilir.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. sql bozulması ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com