Outlook'ta Yanıtlamadığınız Önemli E-postaları Otomatik Olarak Vurgulama

Önemli e-postaları yanıtlamayı hatırlamak için, Outlook'un yanıtlamadığınız önemli e-postaları vurgulamak için belirli bir açık renkle göstermesini isteyebilirsiniz. Şimdi, bu makale size onu nasıl alacağınızı öğretecek.

Hiç önemli e-postaları kaçırdığınız ve zamanında yanıtlamadığınız oldu mu? Bu tür sorunlarla karşılaştıysanız, belki de Outlook'un yanıtlamadığınız önemli e-postaları vurgulayacağını umarsınız. Şimdi, aşağıda VBA ile bunu başarmanız için size rehberlik edeceğiz. VBA'ya aşina değilseniz, lütfen önceki makaleme bakın - “Outlook'unuzda VBA Kodunu Nasıl Çalıştırırsınız?" Bu sırada.

Yanıtlamadığınız Önemli E-postaları Otomatik Olarak Vurgulayın

1. En başta, Outlook'ta "Alt + F11" aracılığıyla VBA düzenleyicisine erişin.
2. Ardından, yeni pencerede aşağıdaki kodu “ThisOutlookSession” projesine kopyalayın.

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Bundan sonra, imleci “Application_Startup” makrosunu açın ve “F5”e basın.
4. Daha sonra bu pencereyi kapatın.
5. Daha sonra, Inbox'taki öğeler için koşullu biçimlendirme kuralı oluşturmak üzere aşağıdaki adımları izleyin.

• Öncelikle, “Gelen Kutusu” klasörüne geçin.
• Ardından, “Görünüm” sekmesine dönün ve “Ayarları Görüntüle” ye tıklayın.
• Yeni iletişim kutusunda, "Koşullu Biçimlendirme" düğmesini tıklayın.
• Bir sonraki "Koşullu Biçimlendirme" iletişim kutusunda, "Ekle"yi tıklayın ve yeni kural için "Yanıtlanmayan Önemli E-postalar" gibi bir ad girin.
• Daha sonra, “Yazı Tipi…” düğmesine tıklayın ve açılan “Yazı Tipi” iletişim kutusunda yazı tipi stilini ve rengini ayarlayın.
• Yazı tipini belirledikten sonra, “Koşullu Biçimlendirme” iletişim kutusunda “Koşul…” seçeneğine basın.
• Daha sonra “Filtre” ekranında “Gelişmiş” sekmesine iki filtre ekleyin.

1. "Önem" > "eşittir" > "Yüksek"
2. "Yanıtlandı" > "(tam olarak)" > "Hayır"

• Son olarak, bu biçimlendirme kuralını kaydetmek için bir dizi “Tamam”a tıklayın.

6. Inbox'a döndükten sonra, yanıtlamadığınız tüm önemli e-postalar belirli bir yazı tipi ve renkte vurgulanmıştır.

Outlook Veri Korumasında Gevşeklik Etmeyin

Sayısız kullanıcı, veri bozulmasının asla akıllarına gelmeyeceği düşüncesine sahiptir. Gerçekte, bu tür fikirler tamamen yanlış ve risklidir. Most küçücük bir hata kolaylıkla veri kaybına neden olabilir. Örneğin, bilinmeyen e-postalardaki kötü amaçlı bir bağlantıya yanlışlıkla tıklarsanız, Outlook dosyanız virüs bulaşabilir ve hatta zarar görebilir. Bu nedenle, düzenli PST yedeklemesinde ısrar etmek ve güçlü bir düzeltme aracı hazırlamak gibi veri koruma konusunda her zaman dikkatli olmalısınız. DataNumen Outlook Repairolabilir Outlook'u düzelt bir anda sorunlar.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. mdf'yi kurtar ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com