Paano Mag-e-export ng Impormasyon ng Mga Papasok na Email sa isang Excel File na may Outlook VBA

Maraming mga gumagamit ang umaasa na ang Outlook ay maaaring awtomatikong i-export ang pangunahing impormasyon ng mga papasok na email sa isang file na Excel. Titingnan ng artikulong ito ang kinakailangang ito at magpapakilala ng isang mabilis na pamamaraan sa pamamagitan ng Outlook VBA.

Minsan, sa ilang kadahilanan, tulad ng mga istatistika ng mail, maaaring madalas mong kailanganing i-export ang mga email sa isang file na Excel. Pangkalahatan, para sa mayroon nang natanggap na mga email, maaari mo lamang magamit ang tampok na "I-import at I-export" upang mai-export ang mga ito sa Excel nang sabay-sabay. Gayunpaman, marahil ay nais mo ring awtomatikong ma-export ng Outlook ang mga papasok na email sa Excel sa sandaling dumating sila sa iyong mailbox. Nang walang anumang pag-aalinlangan, walang ganoong katutubong tampok sa Outlook. Samakatuwid, kailangan mong gumamit ng iba pang mga diskarte, tulad ng isang add-in na 3rd party o Outlook VBA. Tuturuan ka namin dito kung paano ito gawing awtomatiko sa Outlook VBA. Basahin ang upang makuha ang mga hakbang at naaayon sa mga code.

Awtomatikong Pag-export ng Impormasyon ng Mga Papasok na Email sa isang Excel File

1. Sa unang lugar, dapat kang lumikha ng isang file na Excel.

• Magbukas ng isang bagong file na Excel.
• Pagkatapos dapat mong i-type ang "Hindi." sa Cell A1, "Pangalan ng Nagpadala" sa Cell B1, "Address ng Nagpapadala ng Email" sa Cell C1, at "Paksa ng Email" sa Cell D1, at "Natanggap na Oras" sa Cell E1, tulad ng sumusunod na imahe.
• Panghuli i-save ito sa iyong ninanais na pangalan at nais na folder.

2. Pagkatapos nito, dapat mong ilunsad ang Outlook.
3. Pagkatapos ay pindutin ang "Alt + F11" na mga key button, na magdadala sa iyo sa VBA editor.
4. Susunod sa popup window, dapat mong i-double click ang "ThisOutlookSession" sa kaliwang bahagi.
5. Kasunod, sa window ng proyekto na "ThisOutlookSession", kailangan mong kopyahin at i-paste ang mga sumusunod na VBA code dito.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Mamaya dapat mong lagdaan ang code na ito.
7. Kasunod nito, restart Outlook upang buhayin ang bagong proyekto ng VBA.
8. Sa paglaon, mula ngayon, ang lahat ng mga papasok na email ay awtomatikong mai-export sa preset na file ng Excel sa sandaling mapunta sila sa iyong folder na Inbox. Ang excel file ay magiging katulad ng sumusunod na imahe:

Iwasang Masakit ang PST Data Corruption

Ang Outlook ay kumita ng maraming kudos dahil sa iba't ibang mga tampok nito. Gayunpaman, hindi ito nangangahulugang walang katotohanan. Maaari pa rin itong makompromiso anumang oras. Halimbawa, kung madalas mong isara nang hindi tama ang iyong Outlook, malamang na ang iyong data ng PST ay mailalagay sa peligro. Sa kasong ito, kung nais mo ayusin ang PST data, kailangan mong kumuha ng recourse sa isang karanasan na tool, tulad ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang bawiin mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa