2 Mabilis na Paraan para I-export ang Listahan ng Lahat ng Na-flag na Outlook Email sa Excel

Kung gusto mong i-export ang listahan ng lahat ng na-flag na email mula sa iyong Outlook mailbox patungo sa Excel, maaari mong gamitin ang alinman sa 2 paraan na ibinahagi sa artikulong ito.

Halimbawa, upang matugunan ang lahat ng na-flag na email nang mas napapanahon o maibahagi ang mga ito sa ibang tao, maaari kang umasa na i-export ang mga ito sa isang Excel worksheet. Dito ay ipakikilala namin ang 2 mga diskarte upang mapagtanto ito. Ang nauna ay gumagamit ng karaniwang feature na "Import at Export" pagkatapos makahanap ng mga na-flag na email. To be honest, medyo nakakapagod. Kaya, sa huli, ituturo namin sa iyo ang isang mas maginhawang paraan na naaangkop sa VBA.

Paraan 1: Manu-manong I-export ang Lahat ng Nahanap na Na-flag na Email

1. Una sa lahat, mag-click sa box para sa paghahanap sa itaas ng listahan ng mail.
2. Pagkatapos, i-click ang “Lahat ng Mail Items” sa grupong “Scope” sa tab na “Search”.
3. Susunod, i-click ang button na "Na-flag" sa pangkat na "Tukuyin".
4. Pagkatapos ng lahat ng na-flag na email na ipinapakita sa listahan, pumili ng isang mail at pindutin ang "Ctrl + A" upang piliin ang lahat ng mga ito.
5. Pagkatapos, pindutin ang "Ctrl + Shift + V" key shortcut.
6. Sa bagong dialog box, lumikha ng bagong folder sa ilalim ng Outlook file.
7. Sa ibang pagkakataon, piliin ang bagong nilikhang folder at i-click ang "OK", na maglilipat sa lahat ng natagpuang na-flag na email sa bagong folder.
8. Pagkatapos, i-click ang "File" > "Buksan" > "Import",
9. Sa popup dialog box, piliin ang "I-export sa isang file" > "Next" > "Microsoft Excel 97-2003" > "Next".
10. Sa bagong screen, piliin ang tamang folder at pindutin ang "Next".
11. Pagkatapos, sundin ang mga wizard upang makumpleto ang "I-export".
12. Makakakuha ka ng bagong Excel file, na ipinapakita bilang sumusunod na screenshot.

Paraan 2: I-export ang Listahan ng Lahat ng Na-flag na Email sa pamamagitan ng VBA

1. Sa Outlook, pindutin ang “Alt + F11” para ma-trigger ang VBA editor.
2. Pagkatapos, paganahin ang "MS Excel Object" alinsunod sa "Paano Magdagdag ng isang Object Library Sanggunian sa VBA".
3. Susunod, kopyahin ang VBA code sa ibaba sa isang module.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Panghuli, ilagay ang cursor sa subroutine na “ExportAllFlaggedEmailsToExcel” at pindutin ang “F5” key button.
5. Pagkatapos, pumili ng Outlook file sa bagong dialog box.
6. Kapag nakakuha ka ng "Nakumpleto" na prompt, makakakuha ka rin ng bagong Excel file, tulad ng larawan sa ibaba.

Protektahan ang Iyong Pananaw mula sa Korapsyon

Ang Outlook ay madaling kapitan ng mga pagkakamali at katiwalian, kaya isang napakahirap na gawain para sa amin na pangalagaan ang aming data sa Outlook. Walang alinlangan, ang most Ang epektibo at praktikal na paraan ay ang paggawa ng regular na pag-backup ng data para sa Outlook. Bilang karagdagan dito, kinakailangan din para sa amin na makakuha ng isang malakas at mapagkakatiwalaang tool sa pag-aayos ng Outlook, tulad ng DataNumen Outlook Repair. Ito ay magiging kapaki-pakinabang kung tool sa pag-aayos ng inbox walang epekto.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang ayusin SQL Server at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa