วิธีรับการแจ้งเตือนหากไม่ได้รับการตอบกลับอีเมลที่ระบุภายในเวลาที่คาดไว้

บทความนี้จะสอนเคล็ดลับสั้นๆ ในการใช้ VBA เพื่อให้ Outlook แจ้งเตือนคุณโดยอัตโนมัติว่าจะส่งอีเมลแจ้งเตือนเมื่อคุณไม่ได้รับการตอบกลับอีเมลใดภายในระยะเวลาที่กำหนดหรือไม่

ในบางครั้ง สำหรับอีเมลที่มีความสำคัญอย่างยิ่ง คุณจะต้องตั้งตารอการตอบกลับจากอีเมลนั้นอย่างแน่นอน กล่าวอีกนัยหนึ่ง คุณต้องหวังว่าผู้รับจะตอบกลับคุณโดยเร็วที่สุด มิฉะนั้น ตราบใดที่คุณยังไม่ได้รับการตอบกลับภายในเวลาที่คาดหวัง คุณจะส่งอีเมลแจ้งเตือนติดตามผลไปยังผู้รับอีกครั้ง ดังนั้น เพื่อตอบสนองต่อข้อกำหนดนี้ เราจะแนะนำวิธีการที่ใช้ VBA เพื่อทำให้ Outlook เตือนอัตโนมัติและแจ้งให้คุณทราบในกรณีดังกล่าว อ่านต่อเพื่อดูขั้นตอนและรหัสโดยละเอียด

รับการแจ้งเตือนหากไม่ได้รับการตอบกลับอีเมลเฉพาะภายในเวลาที่คาดหวัง

1. เมื่อเริ่มแรก start Outlook ของคุณ
2. จากนั้นคุณจะต้องตั้งเวลาเตือนความจำเฉพาะให้กับอีเมลที่ต้องการ

• ขั้นแรก คลิกขวาที่อีเมลที่ต้องการ
• จากนั้นเลือก “ติดตามผล” > “เพิ่มการแจ้งเตือน”
• ในกล่องโต้ตอบ คุณสามารถตั้งเวลาเตือนความจำให้เหมือนกับเวลาที่คุณต้องการรับการตอบกลับได้

3. หลังจากนั้นกดปุ่ม “Alt + F11” เพื่อเข้าถึงโปรแกรมแก้ไข Outlook VBA
4. ถัดไปในหน้าต่างใหม่ เปิดโครงการ "ThisOutlookSession" และคัดลอกรหัสต่อไปนี้ลงไป

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. จากนั้นลงนามในรหัสนี้
6. ภายหลังเปลี่ยนการตั้งค่าแมโคร Outlook เพื่ออนุญาตแมโครที่เซ็นชื่อแบบดิจิทัล
7. ในที่สุด restarOutlook เพื่อเปิดใช้งานแมโครใหม่ จากนี้ไป Outlook จะทำงานดังต่อไปนี้:

• หากคุณได้รับการตอบกลับอีเมลที่ระบุก่อนที่การแจ้งเตือนจะปรากฏขึ้น Outlook จะล้างการตั้งค่าสถานะโดยอัตโนมัติและปิดใช้งานการแจ้งเตือน
• หากคุณไม่ได้รับการตอบกลับเมื่อการแจ้งเตือนเริ่มทำงาน Outlook จะถามคุณว่าจะส่งอีเมลแจ้งเตือนติดตามผลหรือไม่ หากคุณเลือก "ใช่" อีเมลจะถูกส่งออกไป หากเลือก “ไม่ใช่” ข้อความแจ้งจะหายไปทันที

แก้ไขปัญหา Outlook ที่น่ารำคาญ

เนื่องจาก Outlook มีแนวโน้มที่จะเกิดข้อผิดพลาดเพื่อป้องกัน ความเสียหายของ Outlookคุณไม่เพียงต้องพึ่งพาเครื่องมือกล่องขาเข้า Scanpst.exe เท่านั้น คุณควรเตรียมเครื่องมือซ่อมแซมที่มีประสิทธิภาพและมีชื่อเสียงอีกชิ้นหนึ่ง เช่น DataNumen Outlook Repairซึ่งสามารถกำจัดปัญหาที่น่ารำคาญซึ่ง Scanpst.exe ไม่สามารถจัดการได้

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ sql เสียหาย และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.