วิธีแบทช์ลบที่อยู่อีเมลทั้งหมดที่มีโดเมนเฉพาะออกจากที่ติดต่อ Outlook ของคุณ

โซลูชัน Outlook September 29, 2025

ในบางครั้ง คุณอาจต้องการลบที่อยู่อีเมลทั้งหมดที่มีโดเมนเฉพาะออกจากที่อยู่ติดต่อของคุณ ในสถานการณ์นี้ คุณต้องไม่เต็มใจทำทีละอย่าง ดังนั้นหน้านี้ost จะสอนวิธีที่ชาญฉลาดยิ่งขึ้นให้กับคุณ

เช่น บริษัทเปลี่ยนชื่อ ในขณะเดียวกัน โดเมนของบริษัทก็ได้รับการเปลี่ยนแปลงเช่นกัน อย่างไรก็ตาม ใน Outlook คุณได้จัดเก็บที่อยู่ติดต่อจำนวนมากในบริษัทนี้ ซึ่งมีที่อยู่อีเมลอยู่ในโดเมนเก่า แน่นอนว่าที่อยู่อีเมลเหล่านี้ใช้ไม่ได้อีกต่อไป ดังนั้น ในสถานการณ์นี้ หากคุณต้องการลบที่อยู่อีเมลเหล่านี้ในคราวเดียว คุณสามารถใช้วิธีต่อไปนี้

แบทช์ลบที่อยู่อีเมลทั้งหมดที่มีโดเมนเฉพาะออกจากผู้ติดต่อ

สำหรับเป็นtart เข้าถึงโปรแกรมแก้ไข Outlook VBA ด้วยปุ่มลัด – “Alt + F11”
จากนั้นในหน้าต่างใหม่ ให้วางโค้ด VBA ต่อไปนี้ในโมดูลว่าง

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

หลังจากนั้นให้วางเคอร์เซอร์ไว้ในรูทีนย่อย “BatchRemoveAllEmailAddressesInSpecificDomain”
สุดท้ายคลิกปุ่ม "F5" เพื่อทริกเกอร์มาโครนี้
จากนั้นให้ป้อนโดเมนเฉพาะในกล่องโต้ตอบป๊อปอัป
หลังจากคลิก "ตกลง" มาโครจะทำงาน
เมื่อเสร็จสิ้น คุณจะได้รับข้อความเกี่ยวกับผลลัพธ์
ตอนนี้คุณสามารถตรวจสอบผู้ติดต่อได้ ที่อยู่อีเมลทั้งหมดที่มีโดเมนเฉพาะจะต้องหายไป

เก็บรักษาไฟล์ Outlook ของคุณ

เนื่องจากความเสี่ยงรอบๆ Outlook ของคุณเพิ่มมากขึ้นเรื่อยๆ การปกป้องข้อมูล Outlook อันมีค่าของคุณจึงทำได้ยากขึ้น ตัวอย่างเช่น ไม่เพียงแต่คุณควรสำรองข้อมูลเป็นประจำ แต่คุณยังต้องระวังการดำเนินงานของคุณด้วย มันไม่ฉลาดเลยที่จะเชื่อถืออีเมลใดๆ จากผู้ส่งที่ไม่รู้จัก มิฉะนั้น หากมีไวรัส ไฟล์ Outlook ของคุณจะติดไวรัส ถึงเวลานั้นก็ต้องพยายาม ซ่อมแซม Outlook ผ่านเครื่องมือแก้ไขที่น่าทึ่งเช่น DataNumen Outlook Repair.

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้ Sql Server และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.