2 วิธีในการส่งเซลล์ที่เลือกอย่างรวดเร็วในแผ่นงาน Excel เป็นอีเมล Outlook

โซลูชัน Outlook September 29, 2025

ในบางครั้งคุณอาจต้องการแทรกเซลล์ที่เลือกในแผ่นงาน Excel ลงในอีเมล Outlook อย่างรวดเร็วแล้วส่งอีเมลนี้ออกไป บทความนี้จะกล่าวถึงเรื่องนี้เพื่อเสนอ 2 วิธี

บทความก่อนหน้าของฉัน“2 วิธีด่วนในการส่งแผ่นงาน Excel เป็นอีเมล Outlook” ได้สอนวิธีการส่งแผ่นงาน Excel ทั้งหมดเป็นอีเมล อย่างไรก็ตามบางครั้งคุณต้องการส่งเซลล์ที่เลือกในเวิร์กชีตเป็นอีเมลเท่านั้น เพื่อตอบสนองความต้องการนี้เราจะเปิดเผย 2 วิธีให้คุณทราบ คุณสามารถเลือกได้ตามความต้องการของคุณ

วิธีที่ 1: คัดลอกเซลล์ที่เลือกไปยังอีเมลด้วยตนเอง

ถึงtarเปิดไฟล์ Excel ต้นทางและเข้าถึงแผ่นงาน Excel ที่ถูกต้อง
จากนั้นเลือกเซลล์ที่คุณต้องการส่งเป็นอีเมล Outlook
จากนั้นกดปุ่ม "Ctrl + C" ทางลัดเพื่อคัดลอกเซลล์ที่เลือก
หลังจากนั้นเปิดแอปพลิเคชัน Outlook ของคุณ
จากนั้นคลิกที่ปุ่ม "อีเมลใหม่" ในริบบิ้น "หน้าแรก" เพื่อสร้างอีเมล Outlook ใหม่
ต่อมาในหน้าต่างข้อความใหม่ให้คลิกในส่วนเนื้อหาของข้อความ
จากนั้นกดปุ่ม“ Ctrl + V” เพื่อวางเซลล์ Excel ที่คัดลอกไว้ก่อนหน้านี้
สุดท้ายคุณสามารถเขียนอีเมลได้ตามปกติและคลิกปุ่ม "ส่ง" เพื่อส่งออก

วิธีที่ 2: ส่งเซลล์ที่เลือกเป็นอีเมลผ่าน VBA

ในตอนแรกให้เปิดเวิร์กบุ๊ก Excel ต้นทาง
จากนั้นกดปุ่ม“ Alt + F11” เพื่อเข้าถึงตัวแก้ไข Excel VBA
ในหน้าต่างใหม่ให้คลิก“ แทรก”>“ โมดูล” เพื่อแทรกโมดูลใหม่
ถัดไปควรเปิดใช้งาน Microsoft Outlook Object คลิก "เครื่องมือ"> "ข้อมูลอ้างอิง" ในกล่องโต้ตอบป๊อปอัปค้นหาและตรวจสอบ“ Microsoft Outlook Object Librarย”.
จากนั้นคัดลอกโค้ด VBA ต่อไปนี้ลงในโมดูลนี้

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

ในที่สุดคุณสามารถลอง

ประการแรกเลือกเซลล์เฉพาะตามปกติ
จากนั้นกลับไปที่มาโครใหม่แล้วกดปุ่ม F5 เพื่อทริกเกอร์
ในครั้งเดียวอีเมล Outlook ใหม่จะปรากฏขึ้นซึ่งคุณจะเห็นว่ามีการแทรกเซลล์ที่เลือกลงในเนื้อหาอีเมลดังเช่นภาพหน้าจอต่อไปนี้:

ไฟล์ PST มีช่องโหว่เช่นเดียวกับไฟล์ Excel

อย่างที่เราทราบกันดีว่าไฟล์ Excel และเอกสาร Word มีแนวโน้มที่จะเกิดความเสียหาย อันที่จริงสิ่งเดียวกันนี้ถือเป็นจริงสำหรับไฟล์ PST ซึ่งมีรายการทั้งหมดในกล่องจดหมาย Outlook ของคุณ ดังนั้นจึงเป็นงานที่ยากลำบากในการรักษาความปลอดภัยข้อมูล PST ของคุณ หนึ่งในนั้นost มาตรการที่มีประสิทธิภาพคือการสำรองไฟล์อย่างสม่ำเสมอ นอกจากนี้เพื่อให้การช่วยเหลือในทันทีคุณต้องเตรียมเครื่องมือที่มีประสบการณ์ให้ดีขึ้นเช่น DataNumen Outlook Repairซึ่งสามารถ กู้คืน Outlook ข้อมูลโดยไม่ต้องเสียเหงื่อ

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ ซ่อม mdf และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.