Hur man tar bort alla e-postadresser med en viss domän från dina Outlook-kontakter

Ibland kanske du hoppas kunna ta bort alla e-postadresser med en specifik domän från dina kontakter. I den här situationen måste du vara ovillig att göra det en efter en. Således är denna sost lär dig en mycket smartare metod.

Till exempel ändrar ett företag namn. Under tiden ändras också företagsdomänen. Men i Outlook har du lagrat många kontakter i det här företaget, vars e-postadresser är med den gamla domänen. Naturligtvis är dessa e-postadresser inte längre giltiga. Följaktligen kan du använda följande sätt om du vill ta bort dessa e-postadresser på en gång, under denna omständighet.

Batch Ta bort alla e-postadresser med en specifik domän från kontakter

1. För somtart, öppna Outlook VBA-redigeraren med kortkommandon - “Alt + F11”.
2. Sedan, i det nya fönstret, placerar du följande VBA-kod i en tom modul.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Därefter sätter du markören i “BatchRemoveAllEmailAddressesInSpecificDomain” underrutin.
4. Slutligen klickar du på “F5” -tangentknappen för att utlösa detta makro.
5. Ange sedan den specifika domänen popup-dialogrutan.
6. Efter att ha klickat på “OK” körs makrot.
7. När det är klart får du ett meddelande om resultaten.
8. Nu kan du kontrollera kontakterna. Alla e-postadresser med den specifika domänen måste ha försvunnit.

Bevara din Outlook-fil

Med fler och fler risker kring din Outlook blir det allt svårare att skydda dina värdefulla Outlook-data. Till exempel bör du inte bara fortsätta med regelbundna säkerhetskopior av data utan du måste också se upp för din verksamhet. Det är inte klokt att enkelt lita på e-postmeddelanden från okända avsändare. Annars, om den bär virus, kommer din Outlook-fil att infekteras. Vid den tiden måste du försöka Outlook-reparation via ett anmärkningsvärt fixverktyg, till exempel DataNumen Outlook Repair.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive återhämta Sql Server och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com