Hur man automatiskt markerar de viktiga e-postmeddelanden du inte har svarat i Outlook

Outlook-lösningar September 29, 2025

För att komma ihåg att svara på viktiga e-postmeddelanden kanske du vill att Outlook ska visa de viktiga e-postmeddelandena du inte har svarat i en specifik manifestfärg för att markera dem. Nu kommer den här artikeln att lära dig hur du får det.

Har du någonsin missat några viktiga e-postmeddelanden och inte svarat dem i tid? Om du har fått sådana problem kanske du hoppas att Outlook kan lyfta fram de viktiga e-postmeddelanden som du inte har svarat. Nu, i det följande, kommer vi att vägleda dig för att uppnå det med VBA. Förutsatt att du inte känner till VBA, se min tidigare artikel - “Hur du kör VBA-kod i din Outlook”Under tiden.

Markera de viktiga mejlen du inte har svarat automatiskt

  1. I början, öppna VBA-redigeraren via “Alt + F11” i Outlook.
  2. Kopiera sedan koden nedan i projektet ”ThisOutlookSession” i det nya fönstret.
Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

VBA-kod - automatisk uppdatering av svar på e-postmeddelanden

  1. Därefter flyttar du markören till ”Application_Startup ”makro och tryck“ F5 ”.
  2. Senare, stäng det här fönstret.
  3. Följ sedan stegen nedan för att skapa en villkorlig formateringsregel för artiklar i inkorgen.
  • Börja med att byta till mappen "Inkorgen".
  • Vänd dig sedan till fliken "Visa" och klicka på "Visa inställningar".
  • Klicka på knappen "Villkorlig formatering" i den nya dialogrutan."Villkorlig formatering"
  • I nästa dialogruta "Villkorlig formatering" klickar du på "Lägg till" och anger ett namn för den nya regeln, till exempel "Ej svarade viktiga e-postmeddelanden".Skapa ny villkorlig formateringsregel
  • Senare klickar du på "Font ..." -knappen och ställer in typsnitt och färg i popup-dialogrutan "Font".Ange teckensnitt
  • Efter att du har angett typsnitt trycker du på "Villkor ..." i dialogrutan "Villkorlig formatering".
  • Lägg sedan till två filter på skärmen "Filter", på fliken "Avancerat".
  1. "Betydelse"> "lika"> "Hög"
  2. "Svarad"> "är (exakt)"> "Nej"Lägg till två filter
  • I slutändan klickar du på en serie "OK" för att spara denna formateringsregel.
  1. När du har återgått till Inbox har alla viktiga e-postmeddelanden som du inte har svarat markerats i det specifika teckensnittet och färgen.Markerade viktiga e-postmeddelanden som du inte har svarat

Var inte slapp i Outlook Dataskydd

Myriad-användare har fortfarande tankarna att datakorruption aldrig kommer att uppstå för dem. I verkligheten är sådana idéer helt felaktiga och riskabla. Most med tiden kan ett litet misstag enkelt leda till dataförlust. Om du till exempel av misstag klickar på en skadlig länk i okända e-postmeddelanden kan din Outlook-fil vara virusinfekterad och till och med skadas. Därför bör du vara försiktig hela tiden när det gäller dataskydd, som att fortsätta med regelbunden PST-säkerhetskopiering och förbereda ett kraftfullt fixverktyg, som DataNumen Outlook Repair, som kan fixa Outlook problem i ett tag.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive återställa mdf och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com

Kommentarer är stängda.