2 sätt att skriva ut listor över Outlook-uppgifter med olika kategorier på olika sidor

Om du har tilldelat olika färgkategorier till dina Outlook-uppgifter och nu vill skriva ut listor med uppgifter med olika kategorier på olika sidor, kan du hänvisa till den här artikeln. Här kommer vi att dela dig 2 metoder för att få det.

För att klassificera och väl hantera dina uppgifter kanske du har använt färgkategorier på dina uppgifter. Om du nu vill skriva ut listorna över dina uppgifter med olika kategorier på olika sidor, läs gärna vidare. I det följande kommer vi att presentera två sätt att få det.

Metod 1: Skriv ut uppgiftslistor manuellt en efter en

1. Först och främst, i Outlook, gå till rutan "Uppgifter".
2. Öppna sedan en aktivitetsmapp.
3. Tryck sedan på "Ctrl + E" för att aktivera "Sök" menyfliksområdet.
4. Efter det, på fliken "Sök", klicka på knappen "Kategorisera".
5. Välj en färgkategori från rullgardinsmenyn.
6. Då kommer bara uppgifterna med den valda kategorin att finnas kvar i listan.
7. Gå nu till "Arkiv"> "Skriv ut" för att skriva ut den här uppgiftslistan.
8. Skriv sedan på samma sätt ut listorna över uppgifter med de andra färgkategorierna en efter en manuellt.

Metod 2: Batchutskrift av uppgiftslistorna med VBA

1. I början, trigga VBA-redigeraren i enlighet med "Hur du kör VBA-kod i din Outlook".
2. Lägg sedan till referensen till "MS Excel Object Library ”enligt“Hur man lägger till ett objekt Library Referens i VBA".
3. Kopiera sedan följande VBA-kod till en modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Tryck sedan på "F5"-knappen för att köra detta makro direkt.
5. När makrot är klart kommer listorna med uppgifter med olika kategorier att skrivas ut på olika sidor, som visas i följande skärmdump.

Få tillbaka värdefull data från komprometterad PST-fil

Om du är föremål för en otillgänglig PST-fil är ditt nästa steg utan tvekan PST-reparation. I det här fallet kan du först prova reparationsverktyget för inkorgen. Förutsatt att det misslyckas kan du fortsätta med att prova ett annat externt verktyg, som t.ex DataNumen Outlook Repair. Det kan återställa PST-data på kort tid.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive återställa mdf och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com