Si të nxirrni shpejt bashkëngjitjet nga të gjithë skedarët e mesazheve të Outlook në një dosje të Windows

Ndoshta keni ruajtur disa emaile të Outlook në formatin .msg në një dosje Windows. Dhe më vonë, nëse dëshironi të nxirrni bashkëngjitjet nga këta skedarë, mund të përdorni mënyrën e ndarë në këtë artikull.

Është shumë e lehtë të nxjerrësh bashkëngjitjet nga emailet në Outlook-in tënd. Por çfarë ndodh me emailet që janë eksportuar si skedarë .msg në një dosje të Windows? Në përgjithësi, së pari duhet t'i hapni këto skedarë .msg në Outlook tuaj dhe më pas t'i ruani bashkëngjitjet prej tyre një nga një. Ndoshta do ta ndjeni atë shumë të rëndë. Pra, në vijim, ne do t'ju mësojmë një zgjidhje tjetër shumë më të shpejtë.

Ekstraktoni bashkëngjitjet nga të gjithë skedarët e mesazheve të Outlook në një dosje të Windows

1. Për të filluar, start'i përdorni aplikacionin tuaj Outlook dhe të ekzekutoni redaktorin VBA.
2. Më pas, në dritaren "Microsoft Visual Basic për Aplikacione", kopjoni kodin VBA më poshtë në një modul të papërdorur.

Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

3. Më pas, zhvendoseni kursorin në nënprogramin e parë dhe shtypni butonin "F5".
4. Më pas, do t'ju kërkohet të zgjidhni dosjen burimore të Windows në kutinë e dialogut që shfaqet.
5. Pasi të klikoni "OK", makro do të vazhdojë të funksionojë.
6. Kur të përfundojë, do të merrni mesazhin "Përfunduar".
7. Tani, mund të keni akses në dosjen e paracaktuar lokale për ruajtjen e bashkëngjitjeve të nxjerra.

Zgjidh problemet e Outlook në mënyrë efikase

Meqenëse Outlook është padyshim i prirur për gabime, duhet të jeni të kujdesshëm kur merreni me objektet e Outlook, si për shembull të mos u besoni kurrë skedarëve ose lidhjeve të ngulitura në emailet e panjohura etj. Përndryshe, skedari juaj Outlook mund të korruptohet lehtësisht. Në këtë rrethanë, edhe mjeti i brendshëm i rregullimit nuk do të jetë shumë ndihmë. Ajo që mund të drejtoheni është vetëm një mjet i jashtëm me përvojë, si p.sh DataNumen Outlook Repair. Mundet rregulloni PST skedar me lehtësi të lehtë.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë sql i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com