Si të nxirrni shpejt të gjithë marrësit nga skedarët e shumëfishtë të mesazheve të Outlook (.msg).

Disa përdorues dëshirojnë të nxjerrin shpejt të gjithë marrësit nga skedarët e shumëfishtë të mesazheve të Outlook të ruajtur nga emailet e Outlook. Tani, kjo post do ta shikojë këtë për të ndarë një qasje të shpejtë.

Për të nxjerrë marrësit nga një skedar i vetëm mesazhesh Outlook, thjesht mund të klikoni dy herë për ta hapur dhe më pas kopjoni marrësit në dritaren e hapur të Mesazhit. Por, nëse duhet të merreni me një grup skedarësh mesazhesh Outlook, metoda manuale nuk është mjaft efikase. Kështu, ju mund të kërkoni një mënyrë shumë më efikase. Këtu do t'ju prezantojmë një të tillë. Lexoni për të marrë detajet e tij.

Ekstraktoni të gjithë marrësit nga skedarët e shumëfishtë të mesazheve të Outlook (.msg).

1. Për sitart, merrni akses në redaktorin VBA të Outlook sipas "Si të ekzekutoni kodin VBA në Outlook tuaj".
2. Më pas, kopjoni dhe ngjisni kodin e mëposhtëm VBA në një modul bosh.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Më pas, lëvizni kursorin në nënprogramin e parë.
4. Më pas, klikoni butonin "Run" ose shtypni butonin "F5".
5. Më pas, në kutinë e dialogut që shfaqet, zgjidhni dosjen e Windows e cila përmban skedarët e mesazhit burimor të Outlook (.msg).
6. Pas zgjedhjes, klikoni "OK" për të lejuar që makro të vazhdojë të funksionojë.
7. Kur të përfundojë makroja, do të shfaqet një mesazh që liston të gjitha adresat e emailit të marrësve të nxjerrë, siç tregohet në pamjen e mëposhtme të ekranit.

Mbroni të dhënat tuaja të Outlook nga rreziku

Të dhënat e Outlook pa dyshim janë të prirura për korrupsion. Prandaj, është një detyrë mjaft e vështirë për të mbrojtur të dhënat e Outlook. Kërkon që ju të vazhdoni të bëni kopje rezervë të rregullt për të dhënat e Outlook. Gjithashtu, nëse është e mundur, është e kujdesshme dhe e rekomandueshme të përgatitet një Outlook me përvojë dhe profesionale Riparimi i PST mjet, si DataNumen Outlook Repair, në mënyrë që të mund të fitoni shpëtim të menjëhershëm dhe në kohë në rast të korrupsionit të Outlook.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë shërohem Sql Server dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com