Si të eksportoni raportin tuaj të aksesit në a PDF Skedari përmes VBA

Mësoni se si mund të krijoni një funksion VBA që do t'ju lejojë të ruani Raportin tuaj të Qasjes si PDF vetëm me një klikim të një butoni. Nuk ka nevojë të shkoni në Shiritin e Accessit çdo herë!

Raportet e aksesit mund të ruhen manualisht si PDF dosje. Gjithçka që duhet të bëni është:Ruajtur manualisht si PDF Skedar

  1. Hapni raportin.
  2. Shkoni te Shiriti i Access: Të dhënat e jashtme > PDF ose XPS.
  3. Zgjidhni emrin e skedarit dhe shtegun e dosjes ku dëshironi që të ruhet.
  4. Kliko Publish dhe ke mbaruar.

Lehtë, apo jo? Megjithatë, nëse ka nevojë që ju të eksportoni në mënyrë të përsëritur raporte, të themi në baza ditore, kjo mund të jetë pak takuese.

Mos u shqetësoni. Ka një mënyrë më të lehtë. Me vetëm një klikim të një butoni, raporti juaj mund të eksportohet menjëherë në dosjen tuaj të caktuar. Kjo mund të bëhet me ndihmën e VBA. Thjesht ndiqni hapat e mëposhtëm.

Shkarkojeni Tani

Nëse doni të filloni ta përdorni këtë funksion sa më shpejt të jetë e mundur, atëherë mund të:

Shkarkoni bazën e të dhënave të mostrës me kodet VBA Tani

Përndryshe, nëse dëshironi të bëni DIY, mund të lexoni përmbajtjen më poshtë.

Hapat për të krijuar një funksion VBA që ruan raportin e aksesit si PDF Skedar

1. Shtoni një buton komandimi brenda raportit tuaj

Ky artikull supozon se ju tashmë keni krijuar një Raport Akses. Hapeni atë në pamjen e dizajnit dhe shtoni një buton në kokën e Raportit (siç tregohet më poshtë).Shtoni një buton komandues brenda raportit tuaj

Riemërtoni butonin si cmd_exportPDF. Për ta bërë këtë:

  1. Ndërsa jeni në pamjen e dizajnit, zgjidhni butonin.
  2. Hapni fletën e vetive (ALT + Enter).
  3. Shkoni te skeda Tjetër > Emri.
  4. Ndryshoni vlerën e Emrit në cmd_exportPDF.

2. Shtoni kodin për butonin komandues

Për të shtuar kodin, së pari duhet të shtoni një ngjarje On Click në buton.

  1. Me butonin e komandës të zgjedhur, shkoni përsëri te Fleta e Vetive.
  2. Klikoni në skedën Ngjarje.
  3. Kërkoni On Click dhe zgjidhni…
  4. Kur shfaqet menyja Choose Builder, zgjidhni Code Builder dhe klikoni OK.
  5. Kjo do të hapë Redaktuesin VBA.

Tani, kopjoni kodin më poshtë.

Mos harroni të përditësoni vlerat për emrin e skedarit dhe fldrPath. Secili prej tyre ka yll (*) në ​​seksionin e komenteve.

Function FileExist(FileFullPath As String) As Boolean
  Dim value As Boolean
  value = False
  If Dir(FileFullPath) <> "" Then
    value = True
  End If
  FileExist = value
End Function

Private Sub cmd_exportPDF_Click()
 
  Dim fileName As String, fldrPath As String, filePath As String
  Dim answer As Integer
 
  fileName = "Member Contact Details" 'filename for PDF file*
  fldrPath = "C:\Users\Jessica\Desktop\PDF Exports" 'folder path where pdf file will be saved *
 
  filePath = fldrPath & "\" & fileName & ".pdf"
 
  'check if file already exists
  If FileExist(filePath) Then
    answer = MsgBox(prompt:="PDF file already exists: " & vbNewLine & filePath & vbNewLine & vbNewLine & _
      "Would you like to replace existing file?", buttons:=vbYesNo, Title:="Existing PDF File")
    If answer = vbNo Then Exit Sub
  End If
 
  On Error GoTo invalidFolderPath
  DoCmd.OutputTo objecttype:=acOutputReport, objectName:=Me.Name, outputformat:=acFormatPDF, outputFile:=filePath
 
  MsgBox prompt:="PDF File exported to: " & vbNewLine & filePath, buttons:=vbInformation, Title:="Report Exported as PDF"
  Exit Sub
 
  invalidFolderPath:
  MsgBox prompt:="Error: Invalid folder path. Please update code.", buttons:=vbCritical
 
End Sub

Këto rreshta kodi do të:

  1. Së pari kontrolloni nëse a PDF skedari me të njëjtin emër skedar ekziston tashmë në dosjen e specifikuar. Nëse ndodh, do të shfaqet një kërkesë që ju pyet nëse dëshironi ta zëvendësoni me një të re.

Nëse zgjidhni po, raporti do të vazhdojë me procesin e eksportimit. Nëse jo, skedari nuk do të konvertohet në PDF.

  1. Nëse keni futur një shteg dosjeje që nuk ekziston, do të shfaqet një kërkesë për t'ju kërkuar të përditësoni shtegun e dosjes të specifikuar në kod. Procesi i eksportit nuk do të vazhdojë derisa kjo të korrigjohet.
  2. Pasi raporti të jetë eksportuar me sukses, do të shfaqet një kërkesë që tregon se ku PDF skedari u ruajt.

Kjo eshte! Tani është koha për të testuar butonin tuaj.

Nuk mund të hapet baza e të dhënave të aksesit

Gjëja më e tmerrshme që mund t'i ndodhë çdo përdoruesi të Access është të zgjohet një ditë dhe të kuptojë se baza e të dhënave nuk mund të hapet më. Është dëmtuar. Edhe më keq është se kupton se nuk ke qenë në gjendje të bësh kopje rezervë të të dhënave. Mos u shqetëso. DataNumen Inc. krijoi një softuer që mund rregulloni aksesin bazën e të dhënave. Baza e të dhënave juaj ende mund të rikthehet në jetë.

Hyrje e autorit:

Jayme Stack është një ekspert për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë shërim sql dhe produkte softuerike të rimëkëmbjes excel. Për më shumë informacion vizitoni www.datanumen.com

Komentet janë të mbyllura.