Si të eksportoni automatikisht informacionin e emaileve hyrëse në një skedar Excel me Outlook VBA

Shumë përdorues shpresojnë që Outlook të mund të eksportojë automatikisht informacionin parësor të emaileve hyrëse në një skedar Excel. Ky artikull do të shqyrtojë këtë kërkesë dhe do të prezantojë një metodë të shpejtë përmes Outlook VBA.

Ndonjëherë, për disa arsye, të tilla si statistikat e postës, mund t'ju duhet shpesh të eksportoni emailet në një skedar Excel. Në përgjithësi, për emailet ekzistuese të marra, thjesht mund të përdorni veçorinë "Import dhe eksport" për t'i eksportuar ato në Excel me një lëvizje. Megjithatë, ndoshta ju madje dëshironi që Outlook të mund të eksportojë automatikisht emailet hyrëse në Excel sapo të mbërrijnë në kutinë tuaj postare. Pa asnjë dyshim, nuk ka një veçori të tillë origjinale në Outlook. Prandaj, ju duhet të përdorni qasje të tjera, si një shtesë e palës së tretë ose Outlook VBA. Këtu do t'ju mësojmë se si ta bëni atë automatikisht me Outlook VBA. Lexoni për të marrë hapat dhe kodet sipas.

Eksportoni automatikisht informacionin e emaileve hyrëse në një skedar Excel

1. Në radhë të parë, ju duhet të krijoni një skedar Excel.

• Hapni një skedar të ri Excel.
• Pastaj duhet të shkruani "Jo". në qelizën A1, "Emri i dërguesit" në qelizën B1, "Adresa e postës elektronike të dërguesit" në qelizën C1 dhe "Subjekti i emailit" në qelizën D1 dhe "Koha e marrjes" në qelizën E1, si imazhi i mëposhtëm.
• Së fundi ruajeni në emrin dhe dosjen e dëshiruar.

2. Pas kësaj, duhet të hapni Outlook.
3. Më pas shtypni butonat "Alt + F11", të cilat do t'ju sjellin te redaktuesi VBA.
4. Më pas në dritaren që shfaqet, duhet të klikoni dy herë në "ThisOutlookSession" në anën e majtë.
5. Më pas, në dritaren e projektit "ThisOutlookSession", duhet të kopjoni dhe ngjisni kodet e mëposhtme VBA në të.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Më vonë ju duhet të nënshkruani këtë kod.
7. Më pas, restart Outlook për të aktivizuar projektin e ri VBA.
8. Përfundimisht, tani e tutje, të gjitha emailet hyrëse do të eksportohen automatikisht në skedarin e paracaktuar Excel sapo të zbresin në dosjen tuaj të Inbox. Skedari excel do të duket si imazhi i mëposhtëm:

Shmangni korrupsionin e dhimbshëm të të dhënave PST

Outlook ka fituar shumë lavdërime për shkak të veçorive të tij të ndryshme. Megjithatë, kjo nuk do të thotë se është e pagabueshme. Ajo ende mund të komprometohet në çdo kohë. Për shembull, nëse e mbyllni shpesh Outlook-in tuaj në mënyrë jo të duhur, ka shumë të ngjarë që të dhënat tuaja PST të vihen në rrezik. Në këtë rast, nëse dëshironi riparim PST të dhënat, duhet t'i drejtoheni një mjeti me përvojë, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rikuperoni mdf dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com