2 mënyra për të bashkuar shpejt dokumente të shumëfishta Word në një nëpërmjet VBA

Në këtë artikull, ne jemi të lumtur të ndajmë me ju 2 mënyra për të bashkuar shpejt disa dokumente Word në një nëpërmjet VBA.

Në Word, ekziston veçoria e integruar e parazgjedhur për të ndihmuar përdoruesin të kombinojë ose bashkojë disa dokumente në një. Detajet shpjegohen në këtë artikull: Si të kombinoni dhe bashkoni dokumente të shumëfishta Word në një

Me këtë metodë, ju duhet të bëni disa klikime dhe përmbajtja e dokumentit tjetër vjen gjithmonë menjëherë pas asaj të atij të mëparshëm. Prandaj, ne duam t'ju ofrojmë mënyra më të shpejta për ta bërë këtë.

Metoda 1: Bashkoni dokumentet e zgjedhura në një

1. E para dhe e paraost, krijoni një dokument të ri bosh.
2. Aktivizoni redaktorin VBA në Word duke shtypur "Alt+ F11".
3. Pastaj klikoni "Normal".
4. Pastaj klikoni "Fut".
5. Dhe zgjidhni "Modul".
6. Klikoni dy herë në modulin e ri për të hapur hapësirën e redaktimit.
7. Ngjit makronë e mëposhtme atje:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Pastaj klikoni "Run" ose shtypni "F5".
9. Tani në dritaren "Shfleto", zgjidhni skedarë të shumtë duke shtypur "Ctrl" dhe klikoni "OK".
10. Pastaj të gjitha përmbajtjet në skedarët e zgjedhur do të grumbullohen së bashku në dokumentin e ri, me tekstet e secilit dokumenttartingëllon në një faqe të re.

Shënim:

Siç e përmendëm, kjo makro vendos tekstet e secilit dokument në një faqe të re. Por nëse keni nevojë që ato të jenë njëra pas tjetrës, mund të ndryshoni disa rreshta kodi në makro. Thjesht gjeni rreshtin “If nEachSelectedFile < nTotalFiles Then”, fshijeni atë dhe gjashtë rreshtat e ardhshëm gjithashtu.

Metoda 2: Bashkoni të gjitha dokumentet në një dosje në një

Në rast se keni një dosje skedarësh për t'u kombinuar, atëherë kjo makro do të funksionojë bukur.

1. Të starçaktivizoni, instaloni dhe ekzekutoni makro siç përshkruhet në metodën 1.
2. Pastaj zëvendësoni makro me këtë:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Drejtoni makro duke klikuar "Run".
4. Më pas do të shihni të hapur dritaren "Shfleto". Zgjidhni dosjen ku ruani të gjitha dokumentet. Dhe klikoni "OK".

Në mënyrë të ngjashme, tekstet e çdo dokumenti starts në një faqe të re. Për t'i bërë ato të ngjiten njëri pas tjetrit, gjeni dhe fshini rreshtin e kodit “.InsertBreak Type:=wdPageBreak”.

Mbroni dokumentin tuaj Word siç duhet

Një nga mënyrat më të mira për të mbrojtur dokumentet tuaja Word është t'i rezervoni ato rregullisht. Me kopje rezervë në dorë, nuk do t'ju duhet kurrë të keni frikë nga humbja e të dhënave. Përveç kësaj, është gjithashtu e këshillueshme që të merrni një mjet për të riparim docx nëse ndonjë prej tyre do të dëmtohet.

Hyrje e autorit:

Vera Chen është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë Excel i dëmtuar pdf riparimin e produkteve softuerike. Për më shumë informacion vizitoni www.datanumen.com