2 Mënyra të shpejta për të eksportuar listën e të gjitha emaileve të shënuara të Outlook në Excel

Nëse dëshironi të eksportoni listën e të gjitha emaileve të shënuara nga kutia postare e Outlook në Excel, mund të përdorni njërën nga 2 metodat e përbashkëta në këtë artikull.

Për shembull, në mënyrë që të merreni më me kohë me të gjitha emailet e shënuara ose t'i ndani ato me dikë tjetër, mund të shpresoni t'i eksportoni ato në një fletë pune në Excel. Këtu do të prezantojmë 2 qasje për ta realizuar atë. E para përdor veçorinë standarde "Import dhe eksport" pasi të gjejë emailet e shënuara. Për të qenë i sinqertë, është pak e lodhshme. Kështu, në këtë të fundit, ne do t'ju mësojmë një mënyrë më të përshtatshme që aplikon VBA.

Metoda 1: Eksporto me dorë të gjitha emailet e shënuara të gjetura

1. Para së gjithash, klikoni në kutinë e kërkimit mbi listën e postës.
2. Më pas, klikoni "Të gjitha artikujt e postës" në grupin "Fushëveprimi" në skedën "Kërko".
3. Tjetra, klikoni butonin "Flamuruar" në grupin "Përcaktoni".
4. Pas të gjitha emaileve të shënuara në listë, zgjidhni një email dhe shtypni "Ctrl + A" për t'i zgjedhur të gjitha.
5. Më pas, shtypni shkurtoret e tastit "Ctrl + Shift + V".
6. Në kutinë e re të dialogut, krijoni një dosje të re nën skedarin Outlook.
7. Më vonë, zgjidhni dosjen e re të krijuar dhe klikoni "OK", e cila do të zhvendosë të gjitha emailet e gjetura me flamur në dosjen e re.
8. Më pas, klikoni "File" > "Hap" > "Import",
9. Në kutinë e dialogut që shfaqet, zgjidhni "Eksport në një skedar" > "Tjetër" > "Microsoft Excel 97-2003" > "Tjetër".
10. Në ekranin e ri, zgjidhni dosjen e duhur dhe shtypni "Next".
11. Më pas, ndiqni magjistarët për të përfunduar "Eksport".
12. Do të merrni një skedar të ri Excel, i paraqitur si pamja e mëposhtme e ekranit.

Metoda 2: Eksportoni listën e të gjitha emaileve të shënuara përmes VBA

1. Në Outlook, shtypni "Alt + F11" për të aktivizuar redaktorin VBA.
2. Pastaj, aktivizoni "MS Excel Object" në përputhje me "Si të shtoni një Object Library Referenca në VBA".
3. Më pas, kopjoni kodin VBA më poshtë në një modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Së fundi, vendosni kursorin në nënprogramin "ExportAllFlaggedEmailsToExcel" dhe shtypni butonin "F5".
5. Pastaj, zgjidhni një skedar Outlook në kutinë e re të dialogut.
6. Kur të merrni kërkesën "Përfunduar", do të merrni gjithashtu një skedar të ri Excel, si imazhi më poshtë.

Mbroni opinionin tuaj nga korrupsioni

Outlook është i prirur ndaj gabimeve dhe korrupsionit, prandaj është një detyrë shumë e vështirë për ne që të ruajmë të dhënat tona të Outlook. Pa dyshim, most Mënyra efektive dhe praktike është të bëni kopje rezervë të rregullt të të dhënave për Outlook. Përveç tij, është gjithashtu e nevojshme që ne të kemi në dorë një mjet të fuqishëm dhe të besueshëm të rregullimit të Outlook, si p.sh. DataNumen Outlook Repair. Do të jetë e dobishme nëse mjet për riparimin e kutisë hyrëse nuk bën efekt.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë fix SQL Server dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com