Kako prejeti obvestilo, če ne prejmete odgovora na določeno e-pošto v pričakovanem času

Ta članek vas bo naučil hitrega trika z uporabo VBA, s katerim boste Outlooku omogočili, da vas samodejno pozove, ali želite poslati e-poštno obvestilo, ko v določenem času ne prejmete odgovora na določeno e-pošto.

Včasih se boste za življenjsko pomembna e-poštna sporočila zagotovo veselili njegovih odgovorov. Z drugimi besedami, upati morate, da vam bo prejemnik čim prej odgovoril. V nasprotnem primeru, dokler še ne prejmete odgovora v pričakovanem času, boste prejemniku znova poslali naknadno e-poštno obvestilo. Zato bomo kot odgovor na to zahtevo tukaj predstavili metodo, ki uporablja VBA, da vas Outlook v takem primeru samodejno opozori in pozove. Preberite, če želite izvedeti podrobne korake in kode.

Prejmite obvestilo, če ne prejmete odgovora na določeno e-pošto v pričakovanem času

1. Na samem začetku je start vaš Outlook.
2. Nato morate za določeno e-pošto nastaviti določen čas opomnika.

• Najprej z desno miškino tipko kliknite določeno e-pošto.
• Nato izberite »Nadaljevanje« > »Dodaj opomnik«.
• V pogovornem oknu lahko nastavite čas opomnika, ki je enak določenemu času, v katerem želite prejeti odgovor.

3. Po tem pritisnite tipke »Alt + F11« za dostop do urejevalnika Outlook VBA.
4. Nato v novem oknu odprite projekt »ThisOutlookSession« in vanj kopirajte naslednje kode.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Nato podpišite to kodo.
6. Pozneje spremenite nastavitev makra Outlook, da dovolite digitalno podpisane makre.
7. Sčasoma restart Outlook za aktiviranje novega makra. Od zdaj naprej bo Outlook deloval na naslednji način:

• Če ste prejeli odgovor na določeno e-pošto, preden se prikaže opomnik, bo Outlook samodejno počistil zastavico in onemogočil opomnik.
• Če ob sprožitvi opomnika niste prejeli odgovora, vas bo Outlook vprašal, ali želite poslati e-poštno obvestilo o nadaljnjem obvestilu. Če izberete »Da«, bo e-poštno sporočilo poslano. Če izberete »Ne«, bo poziv takoj izginil.

Rešite nadležne težave z Outlookom

Ker je Outlook nagnjen k napakam, da bi preprečili Outlook korupcija, bolje, da se ne zanašate le na orodje za prejeto pošto, Scanpst.exe. Pripravite si drugo močno in ugledno orodje za popravilo, kot je npr DataNumen Outlook Repair, ki lahko odpravi nadležne težave, ki jih Scanpst.exe ne more rešiti.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z sql korupcije in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com