Kako paketno shraniti več osnutkov e-poštnih sporočil kot Outlookove predloge

Morda ste ustvarili več osnutkov e-poštnih sporočil in upate, da jih boste znova uporabili velikokrat. Če je tako, zakaj jih ne shranite paketno kot Outlookove predloge? Ta članek vas bo naučil, kako to storiti naenkrat prek VBA.

Outlook uporabnikom privzeto dovoljuje samo shranjevanje enega e-poštnega sporočila kot predloge hkrati. Z drugimi besedami, več osnutkov e-poštnih sporočil ne morete shraniti kot predloge v velikem obsegu. Kot lahko vidite, ko izberete več kot eno pošto in odprete »Datoteka« > »Shrani kot«, na seznamu »Shrani kot vrsto« ne najdete oblike »Predloga Outlook«, na voljo je samo »Samo besedilo«. Toda v nadaljevanju vam bomo predstavili, kako to množično realizirati.

Paketno shranjevanje več osnutkov e-poštnih sporočil kot Outlookove predloge

1. Na samem začetku sprožite urejevalnik Outlook VBA.
2. V novem oknu »Microsoft Visual Basic for Applications« kopirajte in prilepite spodnjo kodo VBA.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. Po tem je za kasnejšo udobje predlagano, da ta makro pripnete orodni vrstici za hitri dostop (QAT). O podrobnih korakih si lahko preberete "Kako zagnati kodo VBA v Outlooku"
4. Končno lahko posnamete posnetek tako, da sledite spodnjim postopkom.

• Najprej izberite osnutke e-poštnih sporočil, ki jih želite shraniti kot predloge.
• Nato kliknite gumb makra v QAT.
• Ko se makro konča, se prikaže mapa Windows za shranjevanje privzetih Outlookovih predlog. Vidite lahko, da so predloge iz izbranih osnutkov e-poštnih sporočil tam.

Orodje za popravilo prejete pošte lahko še vedno odpove

Ko gre za interno Outlookovo orodje za popravilo – Scanpst, ga bo cenilo veliko število uporabnikov. Nedvomno je ta pripomoček res sposoben rešiti večino majhnih težav v Outlooku. Vendar pa ni povsem brezhibno. Še vedno lahko odpove in povzroči veliko napak. Na primer, v primeru hude Outlook korupcija, ne more popraviti ogrožene datoteke PST. V tem primeru nimate druge možnosti, kot da uporabite močnejše in vrhunsko orodje tretje osebe, kot je npr DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z obnovitev sql in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com