Kako paketno odstraniti vse e-poštne naslove z določeno domeno iz Outlookovih stikov

Včasih morda upate, da boste iz svojih stikov odstranili vse e-poštne naslove z določeno domeno. V tej situaciji verjetno niste pripravljeni storiti tega enega za drugim. Tako je ta post vas bo naučil veliko pametnejše metode.

Na primer, podjetje spremeni ime. Medtem se spremeni tudi domena podjetja. Vendar ste v Outlooku shranili veliko stikov v tem podjetju, katerih e-poštni naslovi so s staro domeno. Seveda ti elektronski naslovi niso več veljavni. Zato lahko v teh okoliščinah, če želite te e-poštne naslove odstraniti naenkrat, uporabite naslednji način.

Paketno odstranite vse e-poštne naslove z določeno domeno iz stikov

1. Kajti kottart, odprite urejevalnik Outlook VBA z bližnjico na tipki – “Alt + F11”.
2. Nato v novem oknu postavite naslednjo kodo VBA v prazen modul.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Po tem postavite kazalec v podprogram »BatchRemoveAllEmailAddressesInSpecificDomain«.
4. Na koncu kliknite tipko "F5", da sprožite ta makro.
5. Nato v pojavno pogovorno okno vnesite določeno domeno.
6. Ko kliknete »V redu«, se bo makro zagnal.
7. Ko se konča, boste prejeli sporočilo o rezultatih.
8. Zdaj lahko preverite kontakte. Vsi e-poštni naslovi z določeno domeno so morali izginiti.

Ohranite Outlookovo datoteko

Z vedno več tveganji, ki obkrožajo vaš Outlook, je vedno težje zaščititi svoje dragocene podatke Outlook. Na primer, ne samo, da morate vztrajati pri rednem varnostnem kopiranju podatkov, ampak morate paziti tudi na svoje delovanje. Ni pametno takoj zaupati e-poštnim sporočilom neznanih pošiljateljev. V nasprotnem primeru bo vaša Outlookova datoteka okužena, če prenaša virus. Takrat morate poskusiti Outlook popravilo prek izjemnega orodja za popravljanje, kot je npr DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z opomore Sql Server in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com