2 spôsoby, ako rýchlo zlúčiť viac dokumentov Word do jedného pomocou VBA

V tomto článku sa s vami radi podelíme o 2 spôsoby, ako rýchlo zlúčiť viac dokumentov Word do jedného pomocou VBA.

V programe Word je predvolená vstavaná funkcia, ktorá pomáha používateľovi kombinovať alebo zlúčiť niekoľko dokumentov do jedného. Podrobnosti sú vysvetlené v tomto článku: Ako kombinovať a zlúčiť viac dokumentov Word do jedného

Pomocou tejto metódy musíte urobiť niekoľko kliknutí a obsah nasledujúceho dokumentu vždy príde hneď po obsahu predchádzajúceho. Preto vám chceme ponúknuť rýchlejšie spôsoby, ako to urobiť.

Metóda 1: Zlúčenie vybraných dokumentov do jedného

1. V prvom radeost, vytvoriť nový prázdny dokument.
2. Spustite editor VBA v programe Word stlačením kombinácie klávesov „Alt + F11“.
3. Ďalej kliknite na „Normálny“.
4. Potom kliknite na „Vložiť“.
5. A zvoľte „Modul“.
6. Dvojitým kliknutím na nový modul otvoríte priestor na úpravy.
7. Vložte tam nasledujúce makro:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Ďalej kliknite na „Spustiť“ alebo stlačte „F5“.
9. Teraz v okne „Prehľadávať“ vyberte viac súborov stlačením klávesu „Ctrl“ a kliknite na tlačidlo „OK“.
10. Potom bude všetok obsah vo vybraných súboroch spojený do nového dokumentu s textom každého dokumentutarna novej stránke.

Poznámka:

Ako sme už spomenuli, toto makro umiestňuje texty každého dokumentu na novú stránku. Ak ale potrebujete, aby boli jeden za druhým, môžete v makre zmeniť niektoré riadky kódu. Stačí nájsť riadok „If nEachSelectedFile <nTotalFiles Then“, odstrániť ho a tiež ďalších šesť riadkov.

Metóda 2: Zlúčenie všetkých dokumentov v priečinku do jedného

Ak máte priečinok so súbormi, ktoré chcete skombinovať, potom toto makro bude fungovať skvele.

1. K starvypnite, nainštalujte a spustite makro podľa popisu v metóde 1.
2. Potom nahraďte makro týmto:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Makro spustíte kliknutím na tlačidlo „Spustiť“.
4. Ďalej uvidíte otvorené okno „Prehliadať“. Vyberte priečinok, do ktorého ukladáte všetky dokumenty. A kliknite na „OK“.

Podobne texty každého dokumentu starna novej stránke. Ak ich chcete navzájom držať za sebou, vyhľadajte a odstráňte riadok kódu „.InsertBreak Type: = wdPageBreak“.

Chráňte svoj dokument Word správne

Jedným z najlepších spôsobov ochrany dokumentov Word je ich pravidelné zálohovanie. Vďaka zálohám v ruke sa už nikdy nebudete musieť báť straty dát. Okrem toho je tiež vhodné zaobstarať si nástroj opraviť docx ak niektorý z nich bude poškodený.

Úvod autora:

Vera Chen je expertka na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane poškodený Excel a pdf oprava softvérových produktov. Pre viac informácií navštívte www.datanumen. S