Ako rýchlo exportovať štatistiku hlasovania z e-mailu programu Outlook do hárka programu Excel

Ak ste poslali e-mail s hlasovacími tlačidlami, potom, čo vám príjemcovia pošlú svoje odpovede, možno budete chcieť spočítať a exportovať štatistiku hlasovania do hárka programu Excel. Takže v tejto strost, naučíme vás, ako to rýchlo dosiahnuť.

Outlook je taký silný, že ponúka dokonca aj funkciu „Hlasovanie“. Môj predchádzajúci článok “Šikovné využitie MS Outlook na hlasovanie”Učil, ako to efektívne využiť. Tiež most Po hlasovaní môžete z niektorých dôvodov pokračovať v exportovaní štatistík hlasovania do hárka programu Excel, napríklad ak si chcete štatistiku vytlačiť. Ale Outlook to predvolene nepodporuje. V nasledujúcich textoch vás teda naučíme, ako si to uvedomiť ako korok.

Exportujte štatistiku hlasovania e-mailom do pracovného hárka programu Excel

1. Hneď na začiatku spustite aplikáciu Outlook.
2. Potom by ste mali stlačiť klávesovú skratku „Alt + F11“ v hlavnom okne programu Outlook.
3. Ďalej v okne „Microsoft Visual Basic for Applications“ by ste mali povoliť „Microsoft Excel Object Library “. Kliknite na „Nástroje“> „Referencia“. Potom v rozbaľovacom dialógovom okne začiarknite políčko pred „Microsoft Excel Object Library “a nakoniec stlačte tlačidlo„ OK “.
4. Potom môžete vložiť nový modul alebo otvoriť nepoužívaný modul.
5. Následne skopírujte a prilepte nasledujúce kódy VBA do tohto modulu.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Potom ste pre pohodlný prístup radšej pridali nové makro na panel s nástrojmi Rýchly prístup.
6. Nakoniec to môžete vyskúšať.

• Najskôr vyberte zdrojový e-mail, ktorý obsahuje hlasovacie tlačidlá.
• Potom kliknite na tlačidlo makra na paneli s nástrojmi Rýchly prístup.
• Po dokončení spustenia tohto makra môžete prejsť do preddefinovaného miestneho priečinka, v ktorom uvidíte nový zošit programu Excel.
• Otvorte tento zošit programu Excel. Teraz uvidíte štatistiku hlasovania, ktorá sa zobrazuje ako obrázok nižšie:

Chyby programu Outlook nemôže nikto dôsledne odvrátiť

Aj keď je program Outlook vybavený rôznymi funkciami, neexistuje žiadna takáto funkcia, ktorá by nám pomohla vyhnúť sa chybám v programe Outlook. Chyby programu Outlook môžu spôsobiť všetky druhy faktorov. Napríklad ak program Outlook často ukončíte nesprávne, pravdepodobne utrpíte Korupcia PST. V takomto scenári vám nezostáva nič iné, ako použiť nejaké silné nástroje na záchranu vášho súboru PST DataNumen Outlook Repair. Získala veľa sláva vďaka vysokej miere zotavenia.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane skorumpovaný mdf a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S