Как быстро экспортировать все вложения изображений электронной почты Outlook на лист Excel

Если вы хотите быстро экспортировать все вложения изображений электронной почты Outlook на лист Excel, вы можете обратиться к этой статье. Здесь мы покажем вам более эффективный способ, чем экспорт вручную.

Когда вы получаете электронное письмо, содержащее ахost вложений изображений, если вы хотите использовать их для создания отчета в Excel, вы должны долго искать способ, который может экспортировать эти изображения в рабочий лист Excel в пакетном режиме. Теперь мы познакомим вас с таким подходом ниже.

Экспорт всех вложений изображений электронной почты на лист Excel

1. Для начала войдите в свое приложение Outlook обычным способом.
2. Затем в окне Outlook нажмите сочетание клавиш «Alt + F11», чтобы открыть окно «Microsoft Visual Basic для приложений».
3. На этом экране вам нужно открыть модуль, который не используется, или сразу вставить новый.
4. Затем вы должны скопировать фрагмент кода VBA ниже в этот модуль.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. После этого можно выйти из макроса.
6. Затем перейдите в «Файл»> «Параметры»> «Панель быстрого доступа», чтобы добавить этот макрос на панель быстрого доступа.
7. Наконец, вы можете попробовать этот макрос прямо сейчас.

• Во-первых, выберите или откройте исходное письмо.
• Затем нажмите кнопку макроса на панели быстрого доступа.
• Когда макрос завершится, вы получите рабочий лист Excel, показанный на следующем снимке экрана:

Защитите файл Outlook от повреждения

Известно, что Outlook подвержен повреждению. Поэтому мы должны понимать, как защитить форму Outlook от порчи. Прежде всего, чтобы блокировать вирусные атаки, необходимо установить антивирусное программное обеспечение и никогда не загружать неизвестные вложения. Кроме того, нам лучше заполучить мощное средство для ремонта, такое как DataNumen Outlook Repair. Он может предложить мost эффективное средство в случае Повреждение Outlook.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая sql восстановление и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com