Как быстро экспортировать все папки и элементы Outlook в разделе «Избранное» в папку Windows

Если вы хотите экспортировать все папки Outlook, а также их элементы в разделе «Избранное», вы можете обратиться к этой статье. Здесь мы покажем вам, как сделать это в кратчайшие сроки.

Как правило, папки и их элементы в разделе «Избранное» имеют большое значение и часто используются. Поэтому иногда вам может понадобиться экспортировать их на локальный диск. Стандартным способом вы должны создать папки Windows в соответствии с папками в «Избранном» и сохранить элементы в виде файлов MSG один за другим на локальном диске. Это слишком утомительно. Следовательно, здесь мы представим гораздо более эффективный способ. Теперь читайте дальше, чтобы получить его.

Экспорт всех папок и элементов в разделе «Избранное» в папку Windows

1. Для начала откройте редактор VBA в Outlook, обратившись к «Как запустить код VBA в Outlook».
2. Затем скопируйте следующий код в пустой модуль.

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. Затем нажмите значок «Выполнить» на панели инструментов.
4. Затем во всплывающем диалоговом окне выберите целевую папку Windows и нажмите «ОК».
5. Когда макрос завершится, отобразится папка Windows.
6. В этой папке Windows папки и их элементы в разделе «Избранное» были экспортированы, как показано на следующем снимке экрана.

Восстановить данные Outlook из резервных копий

Настоятельно рекомендуется регулярно создавать резервные копии файлов Outlook. Это потому, что если вы пострадали от повреждения файла Outlook, вы можете восстановить Outlook данные из резервных копий легко. Но если у вас нет такой резервной копии, вам придется попытаться исправить ошибку Outlook. В то время инструмент восстановления папки «Входящие» не поможет. Вы должны воспользоваться помощью внешнего инструмента исправления, такого как DataNumen Outlook Repair.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая поврежденный sql и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com