2 moduri rapide de a extrage secțiuni din documentul Word

În acest articol, vă vom oferi 2 moduri rapide și ușoare de a extrage secțiuni din documentul dvs. Word într-un altul sau mai multe.

Se întâmplă destul de des să extragi conținut dintr-un document în altul. Și în articolul nostru anterior, am discutat despre cum să extragem pagini din document. Pentru informații detaliate, puteți consulta acest articol: 2 moduri rapide de a extrage pagini individuale din documentul Word

Astăzi, vă vom arăta cum să extrageți după secțiune.    

Metoda 1: Extrageți secțiunea curentă într-un document nou

1. În primul rând, poziționați cursorul în a tarobține secțiunea.
2. Apoi apăsați „Alt+ F11” pentru a invoca editorul VBA în Word.
3. Apoi, în coloana din stânga, faceți clic pe „Normal”.
4. Și în bara de meniu, faceți clic pe „Inserați”.
5. Apoi alegeți „Modul” din meniul derulant.
6. Faceți dublu clic pentru a deschide noul modul și inserați următoarele coduri acolo:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Apoi, faceți clic pe „Run” în bara de meniu sau apăsați „F5”.
8. Apoi va apărea fereastra „Răsfoiește”. Alegeți un loc pentru a stoca noul document și faceți clic pe „OK”.
9. Și în caseta „Nume fișier”, introduceți numele pentru noul fișier și faceți clic pe „OK”.

Acum ați extras secțiunea într-un document nou.

Metoda 2: Extrageți fiecare secțiune din document în unele noi individuale

Acest mod vă poate ajuta să procesați în lot toate secțiunile dintr-un document. Desigur, vom avea nevoie și de o macrocomandă.

1. Pentru început, deschide tarobține documentul.
2. Apoi urmați pașii din metoda 1 pentru a instala și rula o macrocomandă.
3. Numai că de data aceasta înlocuiți macrocomanda cu aceasta:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Totuși, în fereastra „Răsfoiește”, alegeți o cale de stocare și faceți clic pe „OK”.

Remediați erorile de cuvinte iritante

Este obișnuit să întâlniți unele erori Word în timp ce îl utilizați. Ar putea fi enervant, trebuie să ne luăm timp recupera cuvântul cât mai repede posibil. Deoarece cu cât amânăm mai mult, cu atât pierderea datelor poate fi mai gravă. Prin urmare, se recomandă să obțineți în avans un utilitar de reparații.

Introducerea autorului:

Vera Chen este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv xls corupt și pdf repararea produselor software. Pentru mai multe informații vizitați www.datanumen.com