2 moduri rapide de a găsi sau șterge propoziții care conțin text specific în cuvântul tău

În acest articol, vă vom oferi 2 moduri rapide de a găsi sau șterge propoziții care conțin text specific în Word.

Este cunoscut tuturor că putem folosi funcția „Găsiți și înlocuiți” din Word pentru a găsi cu ușurință toate aparițiile anumitor cuvinte. Atunci nu vom avea nicio problemă să le evidențiem, să le înlocuim sau să le scoatem. După cum vedeți, target este un cuvânt sau o expresie. Astăzi, totuși, suntem încântați să vă spunem modul macro de a găsi sau șterge propoziții care conțin un anumit text.

Metoda 1: Găsiți sau ștergeți propoziții care conțin text specific

1. Pentru început, apăsați „Alt+ F11” pentru a declanșa editorul VBA în Word.
2. Apoi creați un nou modul făcând clic pe „Normal”.
3. Apoi faceți clic pe „Inserare” și alegeți „Modul” pentru a obține unul nou.
4. Și deschideți modulul cu dublu clic.
5. Acum lipiți următoarele coduri:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Apoi faceți clic pe „Run”.
7. Va exista o casetă de introducere, care vă va cere să introduceți text. Doar introduceți textul comun pe care îl conțin toate propozițiile. Faceți clic pe „OK”.
8. Apoi, veți vedea o propoziție care conține textul în selecție, cu o casetă de mesaj. Faceți clic pe „Da” pentru a șterge propoziția și „Nu” pentru a o păstra.
9. După confirmare, următoarea propoziție cu text desemnat este în selecție. Și există și caseta de confirmare. Și anume, macro-ul vă duce să parcurgeți întregul document, găsind tarprimiți propoziții și cereți confirmarea dvs. de fiecare dată.

Metoda 2: Găsiți sau ștergeți propoziții care conțin orice text dintr-o listă

Cu macrocomanda din metoda 1, puteți căuta doar un cuvânt sau o expresie o dată. Cu siguranță, puteți rula macrocomanda în mod repetat pentru a căuta mai multe exemple de cuvinte sau expresii. Pentru a satisface nevoia căutării multiple, vă vom oferi o altă macrocomandă.

1. Mai întâi pune totul tarobțineți texte pe un document nou. Asigurați-vă că fiecare fragment de text ocupă un paragraf fără spațiu în urmă. Închideți și salvați documentul.
2. În continuare, instalați și rulați o macrocomandă cu pașii exacti din metoda 1.
3. Apoi înlocuiți macrocomanda cu aceasta:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Acum se va deschide fereastra „Răsfoiește”. Alegeți documentul doar salvat și faceți clic pe „Deschidere”.
5. Următoarea procedură este aceeași cu cea din metoda 1.

Abordare pentru a trata documentele corupte

Pierderea de date valoroase este absolut devastatoare. Poate chiar să-ți lase afacerea în joc. Pentru a evita o astfel de frustrare, trebuie să puneți mâna pe un Corect de cuvinte instrument cât mai curând posibil. Un astfel de instrument vă va ajuta să câștigați lupta împotriva corupției documentelor.

Introducerea autorului:

Vera Chen este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv repara Excel și pdf repararea produselor software. Pentru mai multe informații vizitați www.datanumen.com