2 moduri de a îmbina rapid mai multe documente Word într-unul singur prin VBA

În acest articol, suntem bucuroși să vă împărtășim 2 moduri de a îmbina rapid mai multe documente Word într-unul singur prin VBA.

În Word, există caracteristica încorporată implicită pentru a ajuta utilizatorul să combine sau să îmbine mai multe documente într-unul singur. Detaliile sunt explicate în acest articol: Cum să combinați și să îmbinați mai multe documente Word într-unul singur

Cu această metodă, trebuie să faceți câteva clicuri, iar conținutul următorului document vine întotdeauna imediat după cel al documentului anterior. Prin urmare, dorim să vă oferim modalități mai rapide de a face acest lucru.

Metoda 1: Îmbinați documentele selectate într-unul singur

1. În primul rând și înainteost, creați un nou document gol.
2. Declanșați editorul VBA în Word apăsând „Alt+ F11”.
3. Apoi faceți clic pe „Normal”.
4. Apoi faceți clic pe „Inserați”.
5. Și alegeți „Modul”.
6. Faceți dublu clic pe modulul nou pentru a deschide spațiul de editare.
7. Lipiți următoarea macrocomandă acolo:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Apoi faceți clic pe „Run” sau apăsați „F5”.
9. Acum, în fereastra „Răsfoiți”, selectați mai multe fișiere apăsând „Ctrl” și faceți clic pe „OK”.
10. Apoi, tot conținutul fișierelor selectate va fi adunat în noul document, cu textele fiecărui documenttarting pe o pagină nouă.

Notă:

După cum am menționat, această macrocomandă pune textele fiecărui document pe o pagină nouă. Dar dacă aveți nevoie să fie unul după altul, puteți modifica unele linii de cod în macro. Găsiți doar linia „Dacă nEachSelectedFile < nTotalFiles Then”, ștergeți-o și următoarele șase rânduri.

Metoda 2: Îmbina toate documentele dintr-un folder într-unul singur

În cazul în care aveți un folder de fișiere de combinat, atunci această macrocomandă va funcționa frumos.

1. Pentru a stardezactivați, instalați și rulați macrocomandă așa cum este descris în metoda 1.
2. Apoi înlocuiți macrocomanda cu aceasta:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Rulați macrocomandă făcând clic pe „Run”.
4. Apoi vedeți fereastra „Răsfoiți” deschisă. Selectați folderul în care stocați toate documentele. Și faceți clic pe „OK”.

În mod similar, textele fiecărui document stareste pe o pagină nouă. Pentru a le face să se lipească unul după altul, găsiți și ștergeți linia de cod „.InsertBreak Type:=wdPageBreak”.

Protejați-vă documentul Word în mod corespunzător

Una dintre cele mai bune modalități de a vă proteja documentele Word este să le faceți copii de rezervă în mod regulat. Cu copiile de rezervă în mână, nu va trebui să vă temeți niciodată de pierderea datelor. În plus, este de asemenea recomandabil să obțineți un instrument reparare docx dacă vreuna dintre ele va fi deteriorată.

Introducerea autorului:

Vera Chen este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv Excel deteriorat și pdf repararea produselor software. Pentru mai multe informații vizitați www.datanumen.com