Cum să primiți o notificare dacă nu primiți răspunsul unui anumit e-mail în timpul așteptat

Acest articol vă va învăța un truc rapid folosind VBA pentru a permite Outlook să vă solicite automat dacă să trimiteți un e-mail de notificare atunci când nu ați primit răspunsul unui anumit e-mail într-un anumit timp.

Uneori, pentru e-mailurile de importanță vitală, veți aștepta cu nerăbdare răspunsurile acestuia. Cu alte cuvinte, trebuie să sperați că destinatarul vă poate răspunde cât mai curând posibil. În caz contrar, atâta timp cât nu ați primit încă răspunsul în timpul estimat, veți trimite din nou un e-mail de notificare ulterioară destinatarului. Prin urmare, ca răspuns la această cerință, aici vom introduce o metodă care utilizează VBA pentru a face ca Outlook să vă avertizeze și să vă solicite automat într-un astfel de caz. Citiți mai departe pentru a obține pașii și codurile elaborate.

Primiți o notificare dacă nu primiți răspunsul unui anumit e-mail în timpul așteptat

1. De la bun început, starla Outlook-ul tău.
2. Apoi, trebuie să setați o anumită oră de memento pentru respectivul e-mail.

• În primul rând, faceți clic dreapta pe e-mailul specific.
• Apoi selectați „Urmărire” > „Adăugați un memento”.
• În caseta de dialog, puteți seta ora de memento la fel ca și ora specifică în care doriți să primiți răspunsul.

3. După aceea, apăsați butoanele tastei „Alt + F11” pentru a accesa editorul Outlook VBA.
4. Apoi, în noua fereastră, deschideți proiectul „ThisOutlookSession” și copiați următoarele coduri în el.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Ulterior, semnați acest cod.
6. Mai târziu, modificați setarea macrocomenzii Outlook pentru a permite macrocomenzile semnate digital.
7. În cele din urmă restart Outlook pentru a activa noua macrocomandă. De acum înainte, Outlook va funcționa după cum urmează:

• Dacă ați primit răspunsul la e-mailul specific înainte ca memento-ul să apară, Outlook va șterge automat semnalizarea și va dezactiva memento-ul.
• Dacă nu ați primit răspunsul când se declanșează mementoul, Outlook vă va întreba dacă trimiteți un e-mail de notificare ulterioară. Dacă selectați „Da”, e-mailul va fi trimis. Dacă selectați „Nu”, solicitarea va dispărea imediat.

Rezolvați problemele enervante ale Outlook

Deoarece Outlook este predispus la erori, pentru a preveni corupție Outlook, ar fi bine să nu vă bazați doar pe instrumentul de inbox, Scanpst.exe. Ar trebui să pregătiți un alt instrument de reparare puternic și de renume, cum ar fi DataNumen Outlook Repair, care poate elimina problemele enervante pe care Scanpst.exe nu le poate rezolva.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv corupție sql și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com