Cum să eliminați în lot toate adresele de e-mail cu un anumit domeniu din contactele dvs. Outlook

Uneori, este posibil să sperați să eliminați toate adresele de e-mail cu un anumit domeniu din persoanele de contact. În această situație, trebuie să nu fii dispus să faci asta unul câte unul. Astfel, acest post vă va învăța o metodă mult mai inteligentă.

De exemplu, o companie își schimbă numele. Între timp, domeniul companiei este și el modificat. Cu toate acestea, în Outlook, ați stocat multe contacte în această companie, ale căror adrese de e-mail sunt cu vechiul domeniu. Desigur, aceste adrese de e-mail nu mai sunt valabile. Prin urmare, în această circumstanță, dacă doriți să eliminați aceste adrese de e-mail dintr-o singură dată, puteți utiliza următorul mod.

Eliminați în lot toate adresele de e-mail cu un anumit domeniu din Contacte

1. Pentru noitart, accesați editorul Outlook VBA prin comanda rapidă – „Alt + F11”.
2. Apoi, în noua fereastră, plasați următorul cod VBA într-un modul gol.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. După aceea, puneți cursorul în subrutina „BatchRemoveAllEmailAddressesInSpecificDomain”.
4. În cele din urmă, faceți clic pe butonul „F5” pentru a declanșa această macrocomandă.
5. Ulterior, introduceți domeniul specific în caseta de dialog pop-up.
6. După ce faceți clic pe „OK”, macro va rula.
7. Când se termină, veți primi un mesaj despre rezultate.
8. Acum, puteți verifica contactele. Toate adresele de e-mail cu domeniul specific trebuie să fi dispărut.

Păstrați fișierul Outlook

Cu tot mai multe riscuri legate de Outlook, este din ce în ce mai dificil să vă protejați datele valoroase din Outlook. De exemplu, nu numai că ar trebui să persisti în backup-uri regulate de date, dar trebuie și să fii atent la operațiunile tale. Nu este înțelept să aveți încredere în orice e-mail de la expeditori necunoscuți. În caz contrar, dacă poartă viruși, fișierul Outlook va fi infectat. În acel moment, trebuie să încerci Repararea Outlook printr-un instrument de reparare remarcabil, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recupera Sql Server și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com