2 maneiras de imprimir as listas de tarefas do Outlook com diferentes categorias em diferentes páginas

Se você atribuiu várias categorias de cores às suas tarefas do Outlook e agora deseja imprimir as listas de tarefas com diferentes categorias em diferentes páginas, consulte este artigo. Aqui vamos compartilhar 2 métodos para obtê-lo.

Para classificar e gerenciar bem suas tarefas, talvez você tenha aplicado categorias de cores às suas tarefas. Agora, se você quiser imprimir as listas de suas tarefas com diferentes categorias em diferentes páginas, continue lendo. A seguir, apresentaremos 2 meios para obtê-lo.

Método 1: Imprima manualmente listas de tarefas uma a uma

1. Primeiro, no Outlook, acesse o painel “Tarefas”.
2. Em seguida, abra uma pasta de tarefas.
3. Em seguida, pressione “Ctrl + E” para ativar a faixa “Pesquisar”.
4. Depois disso, na guia “Pesquisar”, clique no botão “Categorizar”.
5. Na lista suspensa, escolha uma categoria de cor.
6. Assim, apenas as tarefas com a categoria selecionada permanecerão na lista.
7. Agora, vá em “Arquivo” > “Imprimir” para imprimir esta lista de tarefas.
8. Posteriormente, da mesma forma, imprima as listas de tarefas com as outras categorias de cores uma a uma manualmente.

Método 2: imprimir em lote as listas de tarefas por VBA

1. No início, acione o editor VBA de acordo com “Como executar o código VBA no seu Outlook".
2. Em seguida, adicione a referência a “MS Excel Object Library” de acordo com “Como adicionar uma biblioteca de objetosrary Referência em VBA".
3. Em seguida, copie o seguinte código VBA em um módulo.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Depois, pressione o botão da tecla “F5” para executar esta macro imediatamente.
5. Quando a macro terminar, as listas de tarefas com diferentes categorias serão impressas em páginas diferentes, conforme mostrado na captura de tela a seguir.

Recupere dados valiosos do arquivo PST comprometido

Se você está sujeito a um arquivo PST inacessível, seu próximo passo é, sem dúvida, Reparação de PST. Nesse caso, você pode primeiro tentar a ferramenta de reparo da caixa de entrada. Desde que falhe, você pode tentar outra ferramenta externa, como DataNumen Outlook Repair. É capaz de recuperar dados PST rapidamente.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperar mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com