Hvordan batcheksportere bilder og informasjon fra flere kontakter med Outlook VBA

Outlook-løsninger September 29, 2025

Hvis du ønsker å trekke ut kontaktenes bilder og deres primærinformasjon til en mappe på din lokale disk i grupper, må du bruke Outlook VBA. Denne artikkelen vil lære deg hvordan du oppnår det i detalj.

Outlook tillater deg å eksportere kontaktinformasjonen via "Importer og eksporter"-funksjonen. Du kan gå til «Fil» > «Skriv ut» > «Importer» > «Eksporter til en fil».

Eksporter til en fil

Denne funksjonen lar deg imidlertid ikke eksportere kontaktbildene. Derfor, hvis du ønsker å trekke ut både kontaktinformasjon og bilder, må du gå tilbake til Outlook VBA. Følgende er VBA-kodene og trinnene som kan lagre kontaktbildene til en spesifisert lokal mappe og trekke ut kontaktinformasjonen til en tekstfil.

Batch-eksporter bilder og informasjon til flere kontakter

  1. For det første, start Outlook og trykk på "Alt + F11" -tastene.
  2. Da får du tilgang til VBA editor. Nå bør du åpne en modul som ikke er i bruk eller opprette en ny modul ved å "Sett inn"> "Modul".
  3. Deretter kopierer og limer du inn følgende VBA-koder i den nye modulen.
Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

VBA-koder - Batch-eksporter flere kontaktbilder og informasjon

OBS: Kodene ovenfor eksporterer bildene og informasjonen til kontaktene i standard kontaktmappen. Du kan endre de angitte kontaktene.

  • Hvis du vil eksportere bildene og informasjonen til kontaktene i den åpne mappen, bør du erstatte "Set objContacts = ….." med:
Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items
  • Hvis du bare håper å eksportere bildene og informasjonen til utvalgte kontakter, kan du bruke følgende linjer:
Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection
  1. Etter det kan du lukke VBA-editoren og fortsette å legge til det nye prosjektet til Quick Access Toolbar som vanlig.Legg til det nye prosjektet til Qucik Access Toolbar
  2. Til slutt kan du klikke på makroknappen i Quick Access Toolbar. Med en gang vil kontaktbildene og informasjonen eksporteres til den angitte mappen på lokal disk.Eksporter kontaktenes bilder og informasjon

Du kan åpne én tekstfil, der hovedinformasjonen vil bli oppført, som følgende skjermbilde:

Primær kontaktinformasjon i tekstfil

Håndter uventet Outlook-korrupsjon

Det er et ubestridt faktum at Outlook er sårbart. Derfor, hvis du lider av Outlook-korrupsjon, bør du først roe deg ned. Deretter kan du fortsette å reparere korrupt Outlook PST-e-post. Du kan bruke reparasjonsverktøyet for innboks for å prøve. Hvis det mislykkes, har du ikke noe annet valg enn å bruke et mye kraftigere verktøy, som f.eks DataNumen Outlook Repair.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert reparere skadet SQL mdf-database og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.