Slik deaktiverer du hyperkoblingene automatisk i innkommende Outlook-e-poster fra ukjente avsendere

For å blokkere ondsinnede koblinger, bør du konfigurere Outlook til automatisk å deaktivere hyperkoblingene i innkommende e-poster fra ukjente avsendere. Denne artikkelen vil avsløre et stykke VBA-koder som kan hjelpe deg å få det som en kork.

Mange brukere har klaget over at e-postbårne virus angrep Outlook-filen deres. Oftere enn ikke er det fordi de lett stoler på disse e-postene fra ukjente avsendere. Så de laster ned eller klikker på hyperkoblingene i e-postene. Nå, deretter, vil vi dele en metode. Den er i stand til å la Outlook automatisk deaktivere hyperkoblingene til innkommende e-poster fra ukjente avsendere. Hvis du har slike behov, vennligst les videre for å få flere detaljer.

Automatisk deaktiver hyperkoblinger i innkommende e-poster fra ukjente avsendere

1. For somtart, i Outlook, gå til VBA-redigering med "Alt + F11".
2. Deretter legger du til "MS VBScript Regular Expressions"-objekt i det nye skjermbildet i henhold til sost "Hvordan legge til et objekt Library Referanse i VBA".
3. Deretter kopierer og limer du inn følgende kode i "ThisOutlookSession" -prosjektet.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Etter det, aktiver denne makroen enten ved restart Outlook eller trykk på "F5"-tasteknappen i "Application_Startup" underrutine.
5. Siden da, hver gang en e-post som kommer fra avsenderen som ikke er lagret i standard kontaktmappen kommer inn i innboksen, vil Outlook automatisk deaktivere hyperkoblingene i den.

Flere ting av nødvendighet i Outlook-beskyttelse

Siden Outlook er utsatt for skade, er det ganske vanskelig å beskytte Outlook-filen. Her vil vi liste opp flere must-haves under Outlook-databeskyttelse. Først av alt må du sikkerhetskopiere Outlook-dataene dine med jevne mellomrom. Dessuten er det viktig for deg å passe deg for alle potensielle risikoer, som ondsinnede vedlegg eller hyperkoblinger. Sist, men ikke minst, bør du forberede et kraftig Outlook-fixverktøy på forhånd, som DataNumen Outlook Repair. Det kommer garantert til nytte når du trenger det reparere PST fil, men reparasjonsverktøyet for innboks viser feil.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert skadet mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med