3 måter å raskt sette inn seksjonsbrudd i Word-dokumentet ditt

I denne artikkelen vil vi fokusere på å vise deg 3 måter å raskt sette inn seksjonsskift i Word-dokumentet.

Inndelingsskift er nyttige for å dele et dokument inn i seksjoner, kapitler osv. Dessuten er å sette inn seksjonsskift en uunnværlig del av å sette forskjellige topp- eller bunntekster på forskjellige sider.

Normalt må vi navigere til siden og finne markøren i riktig posisjon. Klikk deretter på "Sideoppsett" og "Pause". Og velg deretter en seksjonsskifttype på rullegardinmenyen. En slik sak kan noen ganger være kjedelig. Derfor ønsker vi å redde deg fra den vanlige rutinen og ta i bruk en rask og skitten løsning.

Metode 1: Sett inn et seksjonsskift på en bestemt side

1. Først av alt, trykk "Alt + F11" i Word for å starte VBA-editoren.
2. Opprett deretter en ny modul ved å klikke "Normal" i venstre kolonne.
3. Klikk deretter på "Sett inn"-fanen på menylinjen.
4. Og velg "Modul" på rullegardinmenyen til "Sett inn".
5. Dobbeltklikk på ny modul for å åpne den.
6. Lim inn følgende makro på kodeområdet:

Sub InsertBreakOnSpecificPage()
  Dim strPageNum As String
  Dim nPageNum As Integer
 
  strPageNum = InputBox("Enter a page number: ")
  nPageNum = Int(strPageNum)
 
  Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nPageNum
  ActiveDocument.Bookmarks("\page").Range.Select
  Selection.Collapse wdCollapseEnd
  Selection.InsertBreak Type:=wdSectionBreakContinuous
End Sub

7. Klikk nå på "Kjør" eller trykk på "F5" for å kjøre koder.
8. Skriv deretter inn et sidenummer for tarfå side i spørringsboksen. Og klikk "OK" for å fortsette.

Så langt har du satt inn et seksjonsskift på slutten av side 2.

Merknader:

Hvis du ønsker å skille flere påfølgende sider som en seksjon med bruk av seksjonsskift, må du sette inn seksjonsskift to ganger, en på slutten av siste side av forrige seksjon og en på slutten av siste side av denne nye seksjonen .

I et slikt tilfelle, mens du setter inn den første pausen, bør du huske å skrive inn det riktige tallet som er sidetallet på siste side i forrige avsnitt.

Metode 2: Sett inn et seksjonsskift på hver side i et dokument

1. Først, installer og kjør en makro ved å følge trinnene ovenfor nøyaktig.
2. Bytt deretter ut makroen med denne:

Sub InsertBreakOnEachPage()
  Dim nTotalPageNumber As Integer
 
  For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Collapse wdCollapseEnd
    Selection.InsertBreak Type:=wdSectionBreakContinuous
  Next
End Sub

Denne makroen setter inn et seksjonsskift på slutten av hver side i gjeldende dokument.

Metode 3: Sett inn et seksjonsskift på hver side med flere dokumenter

1. Til å begynne med, legg alle tarfå dokumenter i samme mappe.
2. Installer og kjør makro med riktige instruksjoner.
3. Denne gangen bruker du disse kodene:

Sub InsertBreaksIntoMultiDoc()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nTotalPageNumber As Integer
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "No folder is selected! Please select the target folder."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
      Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
      Application.Browser.Target = wdBrowsePage
      ActiveDocument.Bookmarks("\page").Range.Select
      Selection.Collapse wdCollapseEnd
      Selection.InsertBreak Type:=wdSectionBreakContinuous
    Next
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Makroen skal utløse "Browse"-vinduet. Velg mappen der du oppbevarer dokumenter og klikk "OK".

Prosessen skal ikke ta mer enn noen få sekunder.

Praktisk verktøy for dokumentkorrupsjon

Det er en frustrerende opplevelse å møte skadede dokumenter. I et slikt scenario, et godt og pålitelig verktøy som kan hjelpe reparere Word dokumenter skal kunne lindre ens angst mye. Derfor må du være ekstremt forsiktig når du velger et reparasjonsverktøy. Et utilstrekkelig verktøy kan forårsake ytterligere skade.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert Excel-gjenoppretting og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med