Slik lagrer du automatisk alle vedlegg fra avsendere i et spesifikt domene via Outlook VBA

Hvis du vil la Outlook automatisk lagre alle vedlegg fra avsendere som har e-postadresser i et bestemt domene, kan du lese denne artikkelen. Her vil vi introdusere en rask metode for deg.

Kanskje alle ansatte i din bedrift bruker e-postadressene som er i samme domene. Siden dere ofte sender e-poster med ulike vedlegg til hverandre, vil du kanskje at Outlook automatisk lagrer vedleggene fra slike e-poster. I dette tilfellet vil Outlook bli bedt om å automatisk sjekke e-postens avsenderdomene og automatisk lagre vedlegg. Nå, i det følgende, vil vi dele et stykke VBA-kode som er i stand til å realisere det med uanstrengt letthet.

Lagre automatisk alle vedlegg fra avsendere i et spesifikt domene

1. Først, kjør Outlook VBA editor i henhold til "Hvordan kjøre VBA-kode i Outlook".
2. Sett deretter følgende kode inn i en ubrukt modul.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
   Set objInboxItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
   Dim objMail As Outlook.MailItem
   Dim strSenderAddress As String
   Dim strSenderDomain As String
   Dim objAttachment As Attachment
   Dim strFolderPath As String
   Dim strFileName As String

   If Item.Class = olMail Then
      Set objMail = Item

      'Get sender domain
      strSenderAddress = objMail.SenderEmailAddress
      strSenderDomain = Right(strSenderAddress, Len(strSenderAddress) - InStr(strSenderAddress, "@"))

      'Change to the specific domain as per your needs
      If strSenderDomain = "datanumen.net" Then
         If objMail.Attachments.Count > 0 Then
            For Each objAttachment In objMail.Attachments
                'Change the folder path where you want to save attachments
                strFolderPath = "E:\Attachments\"
                strFileName = objMail.Subject & " " & Chr(45) & " " & objAttachment.FileName
                objAttachment.SaveAsFile strFolderPath & strFileName
            Next
         End If
      End If
   End If
End Sub

3. Etter det, restart Outlook for å aktivere denne makroen.
4. Siden da, hver gang en innkommende e-post kommer inn i innboksen din, vil Outlook automatisk sjekke avsenderdomenet. Hvis det er det samme som det forhåndsdefinerte domenet og det inneholder vedlegg, vil Outlook automatisk lagre vedleggene i en bestemt lokal mappe.

Åpne aldri vedlegg fra avsendere i ukjente domener

Det er tilrådelig å ikke lett stole på og laste ned vedleggene fra de i ukjente domener. Det er fordi de kan komme utstyrt med skadelig programvare eller virus. Når du åpner dem, kan Outlook-filen bli angrepet. Med andre ord kan du bli utsatt for korrupsjon av Outlook-fil. På den tiden til og med scanpst er ute av stand til å hjelpe deg. Din eneste utvei er enten et kraftigere verktøy eller en spesialisert PST-gjenopprettingstjeneste.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert korrupt mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med