Hvordan eksportere mappestrukturen til Outlook-filen til Excel

Hvis du raskt vil eksportere mappestrukturen til Outlook-datafilen til en Excel-arbeidsbok, kan du bruke metoden introdusert i denne artikkelen.

Av noen grunner, for eksempel å logge gjeldende Outlook-mapper og undermapper, håper mange brukere å eksportere mappestrukturen til en Outlook-fil til en ekstern fil, som en Excel-arbeidsbok. I det følgende vil vi dele deg et stykke VBA-kode, som kan hjelpe deg å oppnå det på et blunk.

Eksporter mappestrukturen til Outlook-filen til Excel

1. Til start med, start Outlook-applikasjonen.
2. Trykk deretter "Alt + F11" i hovedvinduet i Outlook.
3. Deretter kommer du inn i Outlook VBA-editoren, der du bør åpne en ubrukt modul.
4. Deretter kan du kopiere følgende VBA-kode inn i denne modulen.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Etter det bør du sørge for at Outlook har aktivert makroer.
6. Til slutt kan du ta et skudd:

• Trykk på F5-tasten i gjeldende makrovindu.
• Etter at makroen er ferdig, vil du få et varsel som ber om "Fullfør".
• Senere kan du gå til den forhåndsdefinerte lokale mappen for å finne en ny Excel-fil. Åpne den og den vil se ut som følgende skjermbilde:

Se aldri bort fra Outlook-feil

Til tross for mengder av muligheter, er Outlook den samme utsatt for feil og korrupsjon som andre e-postklienter. Derfor bør du legge vekt på alle feil i Outlook. Ikke se bort fra dem, vær så snill. Ellers kan akkumulering av feil føre til at Outlook til slutt blir korrupt. Hvis du blir konfrontert med knotete feil, foreslås det å bruke et kraftig verktøy, som f.eks DataNumen Outlook Repair, som kan reparere Outlook feil i løpet av sekunder.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert sql utvinning og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med