Hoe automatisch verschillende lettertypekleuren te gebruiken voor het beantwoorden en doorsturen van e-mails met Outlook VBA

Standaard kunt u Outlook niet automatisch verschillende lettertypekleuren laten gebruiken voor het beantwoorden en doorsturen van e-mails. Daarom, als u een dergelijke vereiste heeft, kunt u deze post een slimme aanpak leren.

In Outlook kunt u alleen een lettertype opgeven dat wordt gebruikt voor het beantwoorden en doorsturen van e-mails. U kunt naar "Bestand"> "Opties" gaan. Ga vervolgens in "Outlook-opties" naar het tabblad "Mail" en klik op de knop "Briefpapier en lettertypen ...". In het volgende venster zie je de knop “Lettertype” bij “Berichten beantwoorden of doorsturen”. Klik erop en dan kunt u een specifieke letterkleur instellen voor het beantwoorden en doorsturen van e-mails.

Veel gebruikers hopen echter verschillende lettertypekleuren te gebruiken voor het beantwoorden of doorsturen van e-mails. Hoewel Outlook hiervoor geen directe functies biedt, kan het nog steeds worden gerealiseerd met VBA-code. Lees nu verder om zo'n stukje VBA-code te krijgen.

Gebruik automatisch verschillende lettertypekleuren voor het beantwoorden en doorsturen van e-mails

1. Voor alstart, start de Outlook-applicatie.
2. Activeer vervolgens de VBA-editor met verwijzing naar "Hoe u VBA-code in uw Outlook uitvoert'.
3. Vervolgens, in overeenstemming met “Hoe u een object kunt toevoegen Library Referentie in VBA", voeg de verwijzing toe naar "MS Word Object Library ”.
4. Kopieer vervolgens de volgende code in het project "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Daarna restart Outlook om deze macro te activeren.
6. Eindelijk kun je het proberen.

• Selecteer of open een e-mail.
• Klik vervolgens op de knop "Beantwoorden". Bij het beantwoorden van e-mail kunt u enkele woorden in de hoofdtekst typen. De kleur van het lettertype moet roze zijn.
• Of klik op de knop "Alles beantwoorden". Voer in de nieuwe e-mail "alles beantwoorden" woorden in hoofdtekst in. De kleur van het lettertype is zeker groen.
• Klik op dezelfde manier op de knop "Doorsturen". In de doorstuurmail worden de nieuwe woorden in blauw weergegeven.

Neem een ​​beroep op betrouwbare software

In geval van Outlook corruptie, Most gebruikers hebben de neiging om hun toevlucht te nemen tot Outlook-herstelsoftware. Er zijn een groot aantal van dergelijke programma's beschikbaar in de markt. En sommige zijn zelfs gratis. Desalniettemin moet u op uw hoede zijn voor die van onbekende bronnen, omdat ze de huidige zaak erger en erger kunnen maken. U moet een betrouwbare en ervaren tool gebruiken, zoals DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder beschadigde sql en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com