Cara Mendapatkan Pemberitahuan Sekiranya Tidak Menerima Balasan E-mel Khusus dalam Masa yang Dijangka

Artikel ini akan mengajar Anda trik cepat menggunakan VBA untuk membiarkan Outlook secara automatik meminta Anda apakah akan mengirim email pemberitahuan ketika Anda belum menerima balasan e-mel tertentu dalam waktu tertentu.

Kadang-kadang, untuk e-mel yang sangat penting, anda pasti akan menantikan balasannya. Dengan kata lain, anda mesti berharap agar penerima dapat membalas anda secepat mungkin. Jika tidak, selagi anda belum menerima balasan dalam jangka masa yang anda jangkakan, anda akan menghantar e-mel pemberitahuan susulan kepada penerima sekali lagi. Oleh itu, sebagai tindak balas kepada keperluan ini, di sini kami akan memperkenalkan kaedah yang menggunakan VBA untuk menjadikan Outlook memberi amaran secara automatik dan meminta anda dalam kes seperti itu. Teruskan membaca untuk mendapatkan langkah dan kod yang terperinci.

Dapatkan Pemberitahuan Sekiranya Tidak Menerima Balasan E-mel Khusus dalam Masa yang Dijangka

1. Pada peringkat awal, start Outlook anda.
2. Kemudian anda perlu menetapkan masa peringatan tertentu ke e-mel tertentu.

• Pertama, klik kanan pada e-mel tertentu.
• Kemudian pilih "Follow Up"> "Add Reminder".
• Dalam kotak dialog, anda boleh menetapkan waktu peringatan sama dengan waktu tertentu di mana anda ingin menerima balasannya.

3. Setelah itu, tekan butang kekunci "Alt + F11" untuk mengakses penyunting Outlook VBA.
4. Selanjutnya di tetingkap baru, buka projek "ThisOutlookSession" dan salin kod berikut ke dalamnya.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Selepas itu, tandatangani kod ini.
6. Kemudian ubah tetapan makro Outlook untuk membenarkan makro yang ditandatangani secara digital.
7. Akhirnya restart Outlook untuk mengaktifkan makro baru. Mulai sekarang, Outlook akan berfungsi seperti berikut:

• Sekiranya anda telah menerima balasan e-mel tertentu sebelum peringatannya muncul, Outlook akan membersihkan bendera secara automatik dan mematikan peringatan tersebut.
• Sekiranya anda belum menerima balasan ketika peringatannya diaktifkan, Outlook akan menanyakan apakah anda akan menghantar e-mel pemberitahuan susulan. Sekiranya anda memilih "Ya", e-mel akan dihantar. Jika memilih "Tidak", permintaan akan hilang sekaligus.

Selesaikan Masalah Outlook yang Mengganggu

Oleh kerana Outlook terdedah kepada ralat, untuk mengelakkannya Rasuah Outlook, anda lebih baik tidak hanya bergantung pada alat peti masuk, Scanpst.exe. Anda harus menyediakan alat pembaikan yang kuat dan ternama, seperti DataNumen Outlook Repair, yang dapat membuang masalah yang menjengkelkan yang tidak dapat diselesaikan oleh Scanpst.exe.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk rasuah sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com