Cara Menonjolkan E-mel Penting secara Auto yang Belum Anda Balas di Outlook

Untuk ingat untuk membalas e-mel penting, anda mungkin ingin Outlook menunjukkan e-mel penting yang belum anda jawab dengan warna manifes tertentu untuk menyerlahkannya. Sekarang, artikel ini akan mengajar anda cara mendapatkannya.

Adakah anda pernah terlepas e-mel penting dan tidak membalasnya tepat pada masanya? Sekiranya anda mengalami masalah seperti itu, mungkin anda berharap Outlook dapat menyerlahkan e-mel penting yang belum anda jawab. Berikut ini, kami akan membimbing anda untuk mencapainya dengan VBA. Dengan syarat bahawa anda tidak biasa dengan VBA, sila rujuk artikel saya sebelumnya - “Cara Menjalankan Kod VBA di Outlook Anda"Sementara itu.

Tandakan secara automatik E-mel Penting yang Belum Anda Balas

1. Pada awalnya, akses editor VBA melalui "Alt + F11" di Outlook.
2. Kemudian, di tetingkap baru, salin kod di bawah ke dalam projek "ThisOutlookSession".

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Selepas itu, gerakkan kursor ke makro "Application_Startup" dan tekan "F5".
4. Kemudian, tutup tetingkap ini.
5. Selepas itu, ikuti langkah di bawah untuk membuat peraturan pemformatan bersyarat untuk item di Peti Masuk.

• Pertama, beralih ke folder "Peti Masuk".
• Kemudian, beralih ke tab "Lihat" dan klik "Tetapan Lihat".
• Di kotak dialog baru, klik butang "Pemformatan Bersyarat".
• Di kotak dialog "Pemformatan Bersyarat" berikutnya, klik "Tambah" dan masukkan nama untuk peraturan baru, seperti "E-mel Penting Tidak Dibalas".
• Kemudian, klik butang "Font ..." dan tetapkan gaya dan warna fon di kotak dialog "Font" pop timbul.
• Setelah menentukan fon, tekan "Condition ..." di kotak dialog "Pemformatan Bersyarat".
• Selanjutnya, di layar "Filter", pada tab "Advanced", tambahkan dua filter.

1. "Kepentingan"> "sama"> "Tinggi"
2. "Dibalas"> "adalah (persis)"> "Tidak"

• Pada akhirnya, klik satu siri "OK" untuk menyimpan peraturan pemformatan ini.

6. Selepas anda kembali ke Peti Masuk, semua e-mel penting yang belum anda jawab telah diserlahkan dalam fon dan warna tertentu.

Jangan Lemah dalam Perlindungan Data Outlook

Ramai pengguna masih berpendapat bahawa kerosakan data tidak akan berlaku kepada mereka. Pada hakikatnya, idea sedemikian adalah salah sama sekali dan berisiko. Kebanyakan masa, kesilapan kecil boleh mengakibatkan kehilangan data dengan mudah. ​​Contohnya, jika anda secara tidak sengaja mengklik pautan berniat jahat dalam e-mel yang tidak diketahui, fail Outlook anda mungkin dijangkiti virus dan juga rosak. Oleh itu, anda harus sentiasa berhati-hati dalam perlindungan data, seperti meneruskan sandaran PST secara berkala dan menyediakan alat pembaikan yang ampuh, seperti DataNumen Outlook Repair, yang boleh betulkan Outlook masalah dalam sekelip mata.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulih mdf dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com