2 Kaedah Pantas untuk Mencari Semua E-mel yang Diteruskan dalam Outlook Anda

Sekiranya anda ingin mencari dengan cepat semua e-mel yang anda kirimkan kepada orang lain di Outlook, anda boleh membaca artikel ini. Di sini kami akan berkongsi 2 cara yang cekap dengan anda.

Seperti yang kita semua ketahui, e-mel yang diteruskan mengandungi ikon anak panah kanan biru. Sangat mudah untuk mengenalinya di antara sebilangan besar e-mel. Kadang-kadang, anda mungkin ingin memeriksa semua yang diteruskan dalam Outlook anda. Dalam kes ini, untuk keselesaan, anda harus mencari dan mengumpulkannya di tempat yang sama. Outlook tidak memberikan kriteria langsung untuk pengguna mencari e-mel yang diteruskan. Walau bagaimanapun, anda masih dapat mencapainya dengan 2 cara berikut.

Kaedah 1: Cari E-mel yang Diteruskan dalam Satu Folder

1. Sebagai permulaan, buka folder mel, seperti "Peti Masuk".
2. Kemudian, beralih ke tab "Lihat" dan klik butang "Lihat Tetapan".
3. Selanjutnya, di kotak dialog pop timbul, klik butang "Tapis".
4. Selanjutnya, dalam dialog baru, beralih ke tab "SQL".
5. Setelah itu, periksa pilihan "Edit kriteria ini secara langsung. Semua tab lain tidak akan tersedia ”di bahagian bawah.
6. Kemudian, masukkan kursor di kotak di atas dan salin kriteria berikut ke dalamnya.

http://schemas.microsoft.com/mapi/proptag/0x10810003 = 104

7. Akhirnya, klik rangkaian "OK" untuk menyimpan tetapan paparan.
8. Apabila kembali ke folder, anda akan mendapati bahawa hanya e-mel yang dihantar di sana, seperti gambar di bawah.

Kaedah 2: Cari E-mel yang Diteruskan dalam Semua Folder

1. Untuk sebagaitart, lancarkan editor Outlook VBA melalui "Alt + F11".
2. Kemudian, masukkan kod VBA berikut ke dalam modul.

Sub GetEmailForwardedStatus()
    Dim objPSTFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Process all folders in your default Outlook file
    Set objPSTFolders = Application.Session.GetDefaultFolder(olFolderInbox).Parent.Folders
 
    For Each objFolder In objPSTFolders
        If objFolder.DefaultItemType = olMailItem Then
           Call ProcessFolders(objFolder)
        End If
    Next
End Sub

Sub ProcessFolders(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objForwardedProperty As Outlook.UserProperty
    Dim strForwardedStatus As String
    Dim objSubFolder As Outlook.Folder
 
    'Get the forwarded status of all mails
    For i = objFolder.Items.Count To 1 Step -1
        If TypeOf objFolder.Items(i) Is MailItem Then
           Set objMail = objFolder.Items(i)
 
           Set objForwardedProperty = objMail.UserProperties.Find("Forwarded", True)
           If objForwardedProperty Is Nothing Then
              Set objForwardedProperty = objMail.UserProperties.Add("Forwarded", olText, True)
           End If
 
           strForwardedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If strForwardedStatus = 104 Then
              objForwardedProperty.Value = "Yes"
           Else
              objForwardedProperty.Value = "No"
           End If
 
           objMail.Save
        End If
    Next
 
    'Process subfolders recursively
    If objFolder.Folders.Count > 0 Then
       For Each objSubFolder In objFolder.Folders
           If objSubFolder.DefaultItemType = olMailItem Then
              Call ProcessFolders(objSubFolder)
           End If
       Next
    End If
End Sub

3. Seterusnya, klik pada subrutin pertama dan tekan kekunci "F5".
4. Selepas itu, keluar dari editor VBA.
5. Selepas itu, dalam senarai folder mel, klik kanan "Cari Folder" dan pilih "Folder Cari Baru".
6. Di kotak dialog pop timbul, pilih "Buat folder pencarian khusus" dan klik butang "Pilih".
7. Kemudian, dalam dialog "Folder Carian Khusus", masukkan "Email Teruskan" di bidang "Nama" dan klik butang "Kriteria".
8. Kemudian, dalam kotak dialog terbaru, beralih ke tab "Lanjutan" dan tambahkan penapis berikut.

• "Diteruskan"> "adalah (persis)"> "Ya"

9. Akhirnya, klik beberapa "OK" untuk membuat folder carian tersuai.
10. Setelah berjaya membuatnya, dalam folder carian ini, semua e-mel yang diteruskan dalam fail data Outlook lalai telah dikumpulkan di sini, seperti yang ditunjukkan pada gambar di bawah.

Melarikan diri dari Kehilangan Data Outlook

Bagi setiap pengguna biasa Outlook, kehilangan data Outlook pasti tidak dapat diterima. Oleh itu, adalah mustahak untuk membuat beberapa tindakan yang berkesan, termasuk sandaran data biasa untuk fail PST, belajar bagaimana menggunakan alat pembaikan peti masuk serta menyiapkan yang boleh dipercayai dan kuat Pembaikan PST alat, seperti DataNumen Outlook Repair. Dengan persediaan ini, walaupun fail PST rosak, anda masih dapat memulihkannya dengan mudah.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk sql rosak dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com