Kā ātri sapludināt vienumus no vairākām mapēm bez dublikātiem programmā Outlook

Ja vēlaties apvienot visus vienumus no vairākām Outlook mapēm un nodrošināt, ka nav dublikātu, varat izmantot šajā rakstā ievadīto metodi. Tas izmanto VBA kodu, lai palīdzētu jums to izpildīt kā korķi.

Reizēm jūs varat apvienot vienumus no vairākām Outlook mapēm, piemēram, apvienot visus vairāku Outlook kontaktpersonu mapju kontaktus. Šajā situācijā, ja starp šīm mapēm ir dublēti kontakti, jums jācer, ka apvienošanas laikā dublikātus var automātiski noņemt. Šajā gadījumā jūs varat izmantot šo VBA kodu, lai to bez piepūles realizētu.

Apvienot vienumus no vairākām mapēm bez dublikātiem

1. Uz start, palaidiet programmu Outlook.
2. Pēc tam jums vajadzētu piekļūt Outlook VBA redaktoram, nospiežot taustiņa pogu “Alt + F11” Outlook galvenajā ekrānā.
3. Pēc tam logā “Microsoft Visual Basic for Applications” ir jāatver modulis, kas netiek izmantots.
4. Pēc tam šajā modulī jums vajadzētu kopēt šādu VBA kodu.

'Here we take "merging two folders" as an example
Sub MergeOutlookFolders_WithoutDuplicates()
    Dim objSourceFolder As Outlook.Folder
    Dim objTargetFolder As Outlook.Folder
    Dim i, n, x As Long
    Dim objItem As Object
    Dim objDictionary As Object
    Dim strKey As String
 
    Set objSourceFolder = Application.Session.PickFolder
    Set objTargetFolder = Application.Session.PickFolder

    If objSourceFolder.DefaultItemType <> objTargetFolder.DefaultItemType Then
       MsgBox "Error: The two folders are not in same type!", vbExclamation + vbOKOnly
    Else
       'Merge the two folders
       For i = objSourceFolder.Items.count To 1 Step -1
           Set objItem = objSourceFolder.Items.Item(i)
           objItem.Move objTargetFolder
       Next i
 
       Set objDictionary = CreateObject("scripting.dictionary")
 
       'Remove the duplicates
       x = 0
       For n = objTargetFolder.Items.count To 1 Step -1
           Set objItem = objTargetFolder.Items.Item(n)
 
           Select Case objItem.Class
                  Case olMail
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  Case olAppointment
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  Case olContact
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  Case olTask
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
              x = x + 1
           Else
              objDictionary.Add strKey, True
           End If
      Next n
 
      'Prompt you of the count of removed duplicates
      If x <> 0 Then
         MsgBox x & " duplicates removed when merging!", vbInformation + vbOKOnly
      End If
    End If
End Sub

5. Vēlāk jums jāpārbauda Outlook makro iestatījumi, nodrošinot, ka makro ir iespējots.
6. Beidzot jūs varat izmēģināt.

• Pirmkārt, atgriezieties jaunajā moduļa logā.
• Pēc tam nospiediet taustiņu F5, lai aktivizētu šo makro.
• Tad jums jāizvēlas abas apvienojamās mapes. Pirmais ir avots, bet otrais ir tardabū vienu.
• Pēc tam programma Outlook sāks pārvietot visus vienumus no avota mapes uz tardabū vienu. Pa to laiku dublikāti tiks automātiski noņemti.
• Galu galā jūs varat saņemt ziņojumu ar aicinājumu noņemto dublikātu skaitu, piemēram, zemāk redzamo ekrānuzņēmumu:

Sīkas kļūdas var izraisīt lielas avārijas

Neskatoties uz lielisku funkciju daudzumu, Outlook joprojām ir pakļauta kļūdām un korupcijai. Varbūt esat saskāries ar dažādām Outlook problēmām. Daudzi lietotāji sliecas ignorēt nejaušas kļūdas. Tomēr tieši sīkā kļūda izraisa nopietnas Outlook avārijas, kas apdraudēs Outlook failu. Tādējādi nevajadzētu ignorēt nelielas kļūdas. Tā vietā jums tos vajadzētu novērst pēc iespējas ātrāk. Turklāt labāk saglabājiet trāpījumu PST remonts rīks, piemēram, DataNumen Outlook Repair. Pateicoties augstajam atkopšanas līmenim, šī lietderība ir pārspējusi pār saviem vienaudžiem.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sabojāts sql un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar