Kā ātri piestiprināt a PowerPoint Prezentācija uz jūsu Outlook e-pastu

Ja vēlaties iegūt konkrētus a PowerPoint prezentāciju atsevišķai jaunai prezentācijai un pievienojiet to Outlook e-pastam, varat izmantot šajā rakstā dalīto veidu.

Tā vietā, lai piestiprinātu veselu PowerPoint prezentāciju uz e-pastu, ja vēlaties pievienot konkrētus prezentācijas slaidus, vispirms konkrētie slaidi vispirms jānokopē jaunā prezentācijā. Tas ir pārāk apgrūtinoši. Tāpēc šeit mēs parādīsim metodi, kas to var realizēt vienā piegājienā.

Pievienojiet a PowerPoint Prezentācija uz e-pastu

1. Pirmkārt, atveriet konkrēto PowerPoint prezentāciju.
2. Pēc tam PowerPoint lietojumprogrammas logā nospiediet taustiņus “Alt + F11”, lai piekļūtu VBA redaktoram.
3. Pēc tam jaunajā logā izveidojiet jaunu moduli, nospiežot “Insert”> “Module”.
4. Pēc tam šajā modulī nokopējiet un ielīmējiet šādu VBA kodu.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Pēc tam jūs varat aizvērt pašreizējo logu.
6. Vēlāk dodieties uz “Fails”> “Opcijas”> “Ātrās piekļuves rīkjosla”, lai pievienotu jauno makro ātrās piekļuves rīkjoslai.
7. Visbeidzot, jūs varat izmēģināt šo makro.

• Par kātart, atlasiet konkrētos slaidus, kurus vēlaties iegūt.
• Pēc tam ātrās piekļuves rīkjoslā noklikšķiniet uz pogas makro.
• Uzreiz parādīsies Outlook e-pasts, kurā ir PowerPoint prezentācija, kas tiek iegūta no avota prezentācijas.

Izmantojiet efektīvu atkopšanas rīku

Kā mēs visi zinām, programma Outlook ir aprīkota ar iebūvētu remonta utilītu - Scanpst. Tomēr tas var vienkārši tikt galā ar nelieliem programmas Outlook traucējumiem. Ja tas, ar ko jūs saskaras, ir nopietns kaitējums, tas neradīs sekas. Tajā brīdī jums neatliek nekas cits kā atkārtot citu spēcīgu un uzticamu remonta rīku, piemēram, DataNumen Outlook Repair. Ar to jūs varēsiet glābt bojāto Outlook failu.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sabojāts mdf un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar