Kaip greitai ištraukti priedus iš visų „Outlook“ pranešimų failų „Windows“ aplanke

Galbūt Windows aplanke išsaugojote kelis Outlook el. laiškus .msg formatu. Ir vėliau, jei norite išgauti priedus iš šių failų, galite naudoti šiame straipsnyje aprašytą būdą.

Gana lengva ištraukti priedus iš el. laiškų programoje „Outlook“. O kaip el. laiškai, kurie buvo eksportuoti kaip .msg failai į Windows aplanką? Paprastai pirmiausia turite atidaryti šiuos .msg failus „Outlook“, o tada po vieną išsaugoti jų priedus. Galbūt jausitės pernelyg sudėtingai. Taigi, toliau mes išmokysime jus kito, daug greitesnio sprendimo.

Ištraukite priedus iš visų „Outlook“ pranešimų failų „Windows“ aplanke

1. Norėdami pradėti, start savo „Outlook“ programą ir paleiskite VBA redaktorių.
2. Tada lange „Microsoft Visual Basic for Applications“ nukopijuokite toliau pateiktą VBA kodą į nenaudojamą modulį.

Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

3. Tada perkelkite žymeklį į pirmąją paprogramę ir paspauskite klavišo „F5“ mygtuką.
4. Po to iššokančiajame dialogo lange turėsite pasirinkti šaltinio „Windows“ aplanką.
5. Spustelėjus „Gerai“, makrokomandos veiks toliau.
6. Kai tai baigsis, gausite pranešimą „Baigta“.
7. Dabar galite gauti prieigą prie iš anksto nustatyto vietinio aplanko, kad išsaugotumėte išskleisti priedus.

Efektyviai išspręskite „Outlook“ problemas

Kadangi „Outlook“ yra linkusi į klaidas, turite būti atsargūs dirbdami su „Outlook“ objektais, pvz., niekada nepasitikėti failais ar nuorodomis, įterptomis į nežinomus el. laiškus ir pan. Priešingu atveju jūsų „Outlook“ failas gali būti lengvai sugadintas. Tokiomis aplinkybėmis net vidinis taisymo įrankis nepadės. Galite kreiptis tik į patyrusį išorinį įrankį, pvz DataNumen Outlook Repair. Tai gali pataisyti PST failą be vargo.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas sql ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com