Kaip paketu pašalinti visus el. pašto adresus su konkrečiu domenu iš „Outlook“ kontaktų

Kartais galite tikėtis pašalinti visus el. pašto adresus su konkrečiu domenu iš savo kontaktų. Esant tokiai situacijai, jūs turite nenorėti to daryti po vieną. Taigi šis post išmokys jus kur kas protingesnio metodo.

Pavyzdžiui, įmonė pakeičia pavadinimą. Tuo tarpu įmonės domenas taip pat keičiamas. Tačiau programoje „Outlook“ šioje įmonėje išsaugojote daug kontaktų, kurių el. pašto adresai yra sename domene. Žinoma, šie el. pašto adresai nebegalioja. Taigi, esant tokioms aplinkybėms, jei norite vienu metu pašalinti šiuos el. pašto adresus, galite naudoti šį būdą.

Paketas pašalinkite visus el. pašto adresus su konkrečiu domenu iš kontaktų

1. Dėl astart, pasiekite „Outlook VBA“ redaktorių naudodami spartųjį klavišą „Alt + F11“.
2. Tada naujame lange įdėkite šį VBA kodą į tuščią modulį.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Po to perkelkite žymeklį į paprogramę „BatchRemoveAllEmailAddressesInSpecificDomain“.
4. Galiausiai spustelėkite mygtuką „F5“, kad suaktyvintumėte šią makrokomandą.
5. Tada iššokančiajame dialogo lange įveskite konkretų domeną.
6. Spustelėjus „Gerai“, bus paleista makrokomanda.
7. Kai tai baigsis, gausite pranešimą apie rezultatus.
8. Dabar galite patikrinti kontaktus. Visi el. pašto adresai su konkrečiu domenu turi būti dingę.

Išsaugokite „Outlook“ failą

Vis daugiau rizikos, susijusios su „Outlook“, vis sunkiau apsaugoti vertingus „Outlook“ duomenis. Pavyzdžiui, turėtumėte ne tik nuolat kurti atsargines duomenų kopijas, bet ir saugotis savo operacijų. Neišmintinga pasitikėti bet kokiais el. laiškais iš nežinomų siuntėjų. Priešingu atveju, jei jame yra virusas, jūsų „Outlook“ failas bus užkrėstas. Tuo metu jūs turite pabandyti „Outlook“ taisymas naudojant puikų taisymo įrankį, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant atsigauti Sql Server ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com