Outlook 이메일의 모든 이미지 첨부 파일을 한 페이지에만 빠르게 인쇄하는 방법

Outlook 솔루션 2025 년 9 월 29 일

프린터 잉크와 용지를 절약하기 위해 일부 사용자는 이메일에 첨부된 모든 이미지를 페이지당 하나의 이미지가 아닌 한 페이지에만 인쇄하기를 원합니다. 이제 이 글은 그것을 실현하는 방법을 공유할 것이다.

우리 모두 알다시피 이미지를 인쇄하는 것은 프린터 잉크를 상당히 낭비하는 것입니다. 따라서 프린터 잉크와 용지를 절약하기 위해 별도의 페이지에 이미지를 인쇄하는 대신 동일한 페이지에 많은 이미지 첨부 파일을 인쇄하는 것을 선호할 수 있습니다. Outlook은 이러한 기능을 제공하지 않지만 다음과 같은 방법으로 사용할 수 있습니다.

Outlook 이메일의 모든 이미지 첨부 파일을 한 페이지에만 인쇄

에tar함께 Outlook 응용 프로그램을 시작하십시오.
그런 다음 Outlook 창에서 "Alt + F11" 키 버튼을 누릅니다.
다음으로 "Microsoft Visual Basic for Applications" 창으로 이동하여 먼저 "Microsoft Word Object Lib"를 활성화해야 합니다.rar와이".
그런 다음 사용하지 않는 모듈을 열어야 합니다.
그런 다음 다음 VBA 코드를 복사하여이 모듈에 붙여 넣습니다.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

나중에 이메일 목록으로 돌아갈 수 있습니다. 인쇄하려는 사진 첨부 파일이 있는 이메일을 선택하거나 엽니다.
그런 다음 이 매크로를 트리거합니다. 현재 매크로 창에서 "F5" 키를 누르거나 도구 모음에서 "실행" 아이콘을 클릭하십시오.
마지막으로 매크로 실행이 완료되면 원본 이메일의 모든 이미지 첨부 파일이 다음 스크린샷과 같이 한 페이지에 인쇄됩니다.

손상된 Outlook 파일 처리

Outlook에 점점 더 많은 데이터가 저장됨에 따라 Outlook 파일이 취약해지고 있습니다. 다양한 내부 및 외부 요인으로 인해 손상될 수 있습니다. 또한 Outlook 손상을 예측하기 어렵습니다. 따라서 Outlook 손상을 만났을 때 즉각적이고 효과적인 구조를 보장하는 것입니다. 예를 들어, 당신은 전문적인 PST 수리 도구, 같은 DataNumen Outlook Repair 근처에. 산들 바람처럼 손상된 파일을 스캔하고 복원합니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 복구 Sql Server 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM