Word 문서에서 한 문장 단락을 빠르게 찾는 방법

이 p에서ost, 우리는 VBA를 통해 Word 문서에서 모든 한 문장 단락을 찾는 빠른 방법을 보여 드리고자합니다.

때때로 일부 문서에는 서식 및 구조에 대한 매우 구체적인 요구 사항이있을 수 있습니다. 예를 들어, 한 문장으로 된 단락이 허용되지 않을 수 있습니다. 이 단락은 인식하기 어렵지 않지만 시간이 걸리며 특히 긴 문서입니다.

오늘은 문서에서 모든 한 문장 단락을 지정하는 빠른 방법을 제공합니다.

한 문서에서 모든 한 문장 단락 찾기

1. 첫째, Word는 마침표를 문장으로 계산합니다. 그래서“미스터”와 같은 단어가 있다면 또는 "Ms.", Word는이를 문장으로 간주합니다. 이러한 산만 함을 배제하려면 "미스터"를 대체해야합니다. "미스터"와 함께. 그리고 한 문장의 단락 찾기가 끝나면 다시 변경할 수 있습니다. 단어를 바꾸려면 다음 링크를 참조하십시오. Word 문서에서 여러 항목을 찾아 바꾸는 방법
2. 둘째, "Alt + F11"을 눌러 VBA 편집기를 트리거합니다.
3. 그런 다음 "일반"프로젝트를 클릭합니다.
4. 메뉴 모음에서 "삽입"탭을 클릭하고 드롭 다운 메뉴에서 "모듈"을 선택합니다.
5. 다음으로 모듈을 두 번 클릭하여 엽니 다.
6. 모듈에 다음 코드를 붙여 넣으십시오.

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. 마지막으로 "실행"버튼을 클릭하거나 "F5"를 누르십시오.

작업이 완료되었음을 알리는 메시지 상자가 표시됩니다.

여러 문서에서 모든 한 문장 단락 찾기

1. 우선, 모든 것을 넣어야합니다. tar폴더에 문서를 가져옵니다.
2. 그런 다음 다음 매크로를 설치하고 실행합니다.

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. "찾아보기"창이 열리면 문서를 보관할 폴더를 선택하고 "확인"을 클릭합니다.

그러면 매크로가 모든 한 문장 단락을 강조 표시하고 문서를 열어 둡니다. 문서에 한 문장 단락이 포함되어 있지 않으면 닫힙니다. 또한 각 문서의 한 문장 단락 수를 나타내는 메시지 상자가 있습니다.

데이터 손실 사고 처리

사용자 오류 및 갑작스러운 정전으로 인해 Word가 죽을 수 있습니다. 접힌 말씀은 일상 업무에 영향을 미칠뿐만 아니라 문서 손상. 이것은 결코 most 데이터 재난의 짜증나는 부분. 데이터를 즉시 복구하려면 복구 유틸리티를 사용하는 것이 좋습니다.

저자 소개 :

Vera Chen은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 엑셀 복구 pdf 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM