Outlook 연락처 그룹에있는 모든 구성원의 세부 정보를 Excel로 빠르게 내보내는 방법

Outlook 솔루션 2025 년 9 월 29 일

기본적으로 연락처 그룹의 구성원 이름과 이메일 주소만 볼 수 있습니다. 회원의 다른 세부 정보를 얻으려면 이 기사에서 소개한 방법을 사용할 수 있습니다.

연락처 그룹을 두 번 클릭하여 열면 해당 창에서 그룹 구성원의 이름과 이메일 주소만 볼 수 있습니다. 회사, 직책, 전화번호, 회사 주소 등과 같은 회원의 기타 세부 정보를 가져올 수 없습니다. 일반적으로 이러한 세부 정보를 얻으려면 연락처 폴더에서 회원에 해당하는 연락처를 수동으로 찾아야 합니다. 너무 번거롭습니다. 여기서는 이러한 세부 정보를 Excel 통합 문서로 빠르게 내보낼 수 있는 VBA 코드를 보여드리겠습니다.

연락처 그룹의 모든 구성원 세부 정보를 Excel로 내보내기

에tar함께 Outlook 응용 프로그램을 시작하십시오.
그런 다음 기본 Outlook 창에서 "Alt + F11" 키 바로 가기를 눌러야 합니다.
다음으로 새로운 "응용 프로그램용 Microsoft Visual Basic" 창에서 사용하지 않는 모듈을 열거나 새 모듈을 직접 삽입해야 합니다.
그런 다음 다음 VBA 코드를 복사하여이 모듈에 붙여 넣습니다.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

그런 다음 편리한 확인을 위해 새 VBA 프로젝트를 빠른 실행 도구 모음이나 리본에 추가할 수 있습니다.
나중에 Outlook 매크로 보안 수준을 낮음으로 설정합니다.
궁극적으로 시도해 볼 수 있습니다.

먼저 연락처 그룹을 선택합니다.
그런 다음 빠른 실행 도구 모음 또는 리본에서 매크로 버튼을 누릅니다.
즉시 매크로가 실행됩니다.
완료되면 "완료!"라는 프롬프트가 표시됩니다.
그런 다음 미리 정의된 대상 로컬 폴더로 이동하여 새 Excel 파일을 찾을 수 있습니다.
열면 다음 스크린샷과 같은 그룹 구성원의 연락처 세부 정보가 표시됩니다.

Outlook 문제 앞에서 당황하지 마십시오.

팝업 오류 메시지 또는 상관없이 아무도 Outlook 문제를 기꺼이 받아들이지 않습니다. 손상된 Outlook 데이터 파일. 따라서 사용자는 Outlook 문제를 접할 때 당황하는 경향이 있습니다. 이 경우 침착함을 유지하려면 두 가지 필수품을 손에 들고 있어야 합니다. 하나는 현재 Outlook 데이터 백업입니다. 다른 하나는 다음과 같은 강력한 Outlook 수정 소프트웨어입니다. DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM