Outlook 작업에 다양한 색상 범주를 할당했고 이제 다른 페이지에 다른 범주의 작업 목록을 인쇄하려는 경우이 문서를 참조 할 수 있습니다. 여기서 우리는 그것을 얻는 두 가지 방법을 공유 할 것입니다.
작업을 분류하고 잘 관리하기 위해 작업에 색상 범주를 적용했을 수 있습니다. 이제 다른 페이지에 다른 범주의 작업 목록을 인쇄하려면 계속 읽으십시오. 다음에서 우리는 그것을 얻는 두 가지 방법을 소개합니다.
방법 1 : 작업 목록을 하나씩 수동으로 인쇄
- 먼저 Outlook에서 "작업"창에 액세스합니다.
- 그런 다음 작업 폴더를 엽니 다.
- 그런 다음 "Ctrl + E"를 눌러 "검색"리본을 활성화합니다.
- 그 후“검색”탭에서“분류”버튼을 클릭합니다.
- 드롭 다운 목록에서 색상 범주를 선택합니다.
- 그러면 선택한 범주의 작업 만 목록에 남게됩니다.
- 이제 "파일"> "인쇄"로 이동하여이 작업 목록을 인쇄합니다.
- 그런 다음 같은 방법으로 다른 색상 범주가있는 작업 목록을 하나씩 수동으로 인쇄합니다.
방법 2 : VBA로 작업 목록 일괄 인쇄
- 처음에는“Outlook에서 VBA 코드를 실행하는 방법".
- 그런 다음, "MS Excel 개체 라이브러리"에 대한 참조를 다음과 같이 추가하십시오.VBA에서 개체 라이브러리 참조를 추가하는 방법".
- 다음으로 다음 VBA 코드를 모듈에 복사합니다.
Sub PrintTaskList_SpecificColorCategory()
Dim objTasks As Outlook.Items
Dim objTask As Outlook.TaskItem
Dim objDictionary As Object
Dim arrCategory As Variant
Dim varCategory As Variant
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim varKey As Variant
Dim strKey As String
Dim i As Long
Dim bSheetFound As Boolean
Dim nLastRow As Integer
Dim objSheet As Excel.Worksheet
Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
Set objDictionary = CreateObject("Scripting.Dictionary")
'Get All Tasks' Categories
For Each objTask In objTasks
arrCategory = Split(objTask.Categories, ",")
For Each varCategory In arrCategory
If objDictionary.Exists(Trim(varCategory)) = False Then
objDictionary.Add Trim(varCategory), 0
End If
Next
Next
'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
Set objExcelApp = CreateObject("Excel.Application")
Set objExcelWorkbook = objExcelApp.Workbooks.Add
objExcelApp.Visible = True
i = 0
For Each varKey In objDictionary.Keys
strKey = CStr(varKey)
On Error Resume Next
objExcelWorkbook.Sheets(strKey).Select
bSheetFound = (Err = 0)
On Error GoTo 0
If bSheetFound = False Then
i = i + 1
If i < 4 Then
Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
Else
Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
End If
objExcelWorksheet.Name = strKey
End If
With objExcelWorksheet
.Cells(1, 1) = strKey
.Cells(1, 1).Font.Bold = True
.Cells(1, 1).Font.Size = 18
.Cells(2, 1) = "Subject"
.Cells(2, 1).Font.Bold = True
.Cells(2, 2) = "Start Date"
.Cells(2, 2).Font.Bold = True
.Cells(2, 3) = "Due Date"
.Cells(2, 3).Font.Bold = True
End With
For Each objTask In objTasks
If InStr(objTask.Categories, strKey) > 0 Then
nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
With objExcelWorksheet
.Range("A" & nLastRow) = objTask.Subject
.Range("B" & nLastRow) = objTask.startDate
.Range("C" & nLastRow) = objTask.DueDate
End With
End If
Next
objExcelWorksheet.Columns("A:C").AutoFit
Next
'Print out All Sheets in this Excel Workbook
For Each objSheet In objExcelWorkbook.Sheets
objSheet.PrintOut
Next
objExcelWorkbook.Close False
objExcelApp.Quit
End Sub
- 그 후 "F5"키를 눌러이 매크로를 바로 실행하십시오.
- 매크로가 완료되면 다음 스크린 샷과 같이 다른 범주의 작업 목록이 다른 페이지에 인쇄됩니다.
손상된 PST 파일에서 귀중한 데이터 회수
액세스 할 수없는 PST 파일의 영향을받는 경우 의심 할 여지없이 다음 단계는 PST 수리. 이 경우 먼저받은 편지함 복구 도구를 사용해 볼 수 있습니다. 실패한 경우 다음과 같은 다른 외부 도구를 시도 할 수 있습니다. DataNumen Outlook Repair. 빠른 시간에 PST 데이터를 복구 할 수 있습니다.
저자 소개 :
Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM