Outlook의 모든 무료 또는 미정 일정 항목에서 미리 알림을 일괄 제거하는 2 가지 방법

Outlook 솔루션 2025 년 9 월 29 일

"무료"또는 "미정"으로 표시된 일정 항목의 경우 미리 알림을 제거 할 수 있습니다. 이제이 기사에서는 대량으로 얻을 수있는 두 가지 방법을 소개합니다.

모든 일정 항목에 대해 기본 미리 알림 시간을 구성했을 수 있습니다. 이 경우 바쁘거나 부재 중, 약속 있음 또는 미정 항목에 관계없이 항상 미리 알림을 사용할 수 있습니다. 그러나 일반적으로 무료 및 임시 항목에는 실제로 알림이 필요하지 않습니다. 따라서 이러한 항목에서 미리 알림을 일괄 제거하려고합니다. 그래서 여기서 우리는 한 번에 그것을 실현하는 두 가지 방법을 알려줄 것입니다.

방법 1 : 한 일정에서 수동으로 일괄 제거

먼저 달력을 엽니 다.
그런 다음 "보기"탭으로 이동하여 "보기 변경"> "목록"을 클릭합니다.
다음으로“설정보기”버튼을 클릭합니다.
팝업 대화 상자에서 "Group By"버튼을 누르십시오.
그런 다음 다른 새 대화 상자에서 "항목 그룹화 기준"에서 "알림"을 선택하고 "확인"을 클릭합니다.
나중에 "열"버튼을 클릭합니다.
"Show Columns"대화 상자에서 "Show Time As"열을 추가하고 "OK"를 누르십시오.
그런 다음 "확인"을 클릭하여보기 설정을 저장합니다.
일정 항목 목록에서 "알림 : 예"그룹의 모든 사용 가능 / 미정 항목을 찾아 선택합니다.
마지막으로 "Reminder : No"그룹으로 끌어다 놓습니다.

방법 2 : VBA를 사용하여 모든 달력에서 일괄 제거

먼저 "Alt + F11"을 눌러 VBA 편집기를 트리거합니다.
그런 다음 아래의 VBA 코드를 모듈에 복사하십시오.

Sub RemoveReminders_TentativeCalendarItems()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
 
    For Each objStore In Application.Session.Stores
        'Process all Calendar folders
        For Each objFolder In objStore.GetRootFolder.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Long
    Dim objAppointment As Outlook.AppointmentItem
    Dim objSubCalendar As Outlook.Folder
 
    'Remove Reminders from Free/Tentative Calendar Items
    For i = objCalendar.Items.Count To 1 Step -1
        Set objAppointment = objCalendar.Items(i)
        If objAppointment.BusyStatus = olFree Or objAppointment.BusyStatus = olTentative Then
           If objAppointment.ReminderSet = True Then
              objAppointment.ReminderSet = False
              objAppointment.Save
           End If
        End If
    Next
 
    'Process Subfolders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

그 후 커서를 첫 번째 서브 루틴으로 이동합니다.
마지막으로 "F5"키를 누릅니다.
한 번에 무료 또는 임시 일정 항목의 모든 미리 알림이 제거됩니다.

혼란스러운 Outlook 문제에 대처

Outlook에서 PST 파일 손상, 바이러스 감염, 우발적 인 항목 삭제 등과 같은 기타 문제가 발생하는 것은 매우 일반적입니다. 이러한 문제를 제 시간에 효과적으로 해결하려면 안정적인 상태를 유지하는 것이 좋습니다. PST 수리 근처의 도구 DataNumen Outlook Repair. 성가신 Outlook 데이터 손실로부터 당신을 구할 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 수리 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM