Excel 워크 시트에서 선택한 셀을 Outlook 이메일로 빠르게 보내는 2 가지 방법

Outlook 솔루션 2025 년 9 월 29 일

때때로 Excel 워크시트에서 선택한 셀을 Outlook 전자 메일에 빠르게 삽입하고 이 전자 메일을 보낼 수 있습니다. 이 기사에서는 이 소원을 살펴보고 2가지 방법을 제공합니다.

내 이전 기사“2 Excel 워크 시트를 Outlook 이메일로 보내는 빠른 방법”는 전체 Excel 워크시트를 이메일로 보내는 방법을 가르쳐 주었습니다. 그러나 경우에 따라 워크시트에서 선택한 셀만 전자 메일로 보내기를 원할 수 있습니다. 이 요구 사항에 대한 응답으로 여기에서 두 가지 방법을 제공합니다. 취향에 따라 선택하시면 됩니다.

방법 1: 선택한 셀을 전자 메일에 수동으로 복사

먼저 원본 엑셀 파일을 열고 해당 엑셀 워크시트에 접근하세요.
그런 다음 Outlook 전자 메일로 보내려는 셀을 선택합니다.
그런 다음 "Ctrl + C" 단축키를 눌러 선택한 셀을 복사합니다.
그런 다음 Outlook 응용 프로그램을 시작하십시오.
그런 다음 "홈" 리본에서 "새 전자 메일" 버튼을 클릭하여 새 Outlook 전자 메일을 만듭니다.
나중에 새 메시지 창에서 메시지 본문 섹션을 클릭합니다.
그런 다음 "Ctrl + V" 키 버튼을 눌러 이전에 복사한 선택한 Excel 셀을 붙여넣습니다.
마지막으로 평소와 같이 이메일을 작성하고 "보내기" 버튼을 클릭하여 보낼 수 있습니다.

방법 2: 선택한 셀을 VBA를 통해 이메일로 보내기

맨 처음에 원본 Excel 통합 문서를 엽니다.
그런 다음 "Alt + F11" 키 버튼을 눌러 Excel VBA 편집기에 액세스합니다.
새 창에서 "삽입" > "모듈"을 클릭하여 새 모듈을 삽입합니다.
다음으로 Microsoft Outlook 개체를 활성화해야 합니다. "도구" > "참조"를 클릭합니다. 팝업 대화 상자에서 "Microsoft Outlook 개체 라이브러리"를 찾아 선택합니다.
그런 다음 다음 VBA 코드를이 모듈에 복사합니다.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

결국 시도해 볼 수 있습니다.

먼저 평소와 같이 특정 셀을 선택합니다.
그런 다음 새 매크로로 돌아가 F5 키를 눌러 트리거합니다.
다음 스크린샷과 같이 선택한 셀이 이메일 본문에 삽입된 것을 볼 수 있는 새 Outlook 이메일이 즉시 표시됩니다.

PST 파일은 Excel 파일과 동일하게 취약합니다.

아시다시피 Excel 파일과 Word 문서는 손상되기 쉽습니다. 실제로 Outlook 사서함의 모든 항목이 저장된 PST 파일도 마찬가지입니다. 따라서 PST 데이터를 안전하게 보호하는 것은 매우 어려운 일입니다. 가장 효과적인 방법 중 하나는 파일을 정기적으로 백업하는 것입니다. 또한 즉각적인 복구를 위해 전문 도구를 준비해 두는 것이 좋습니다. DataNumen Outlook Repair할 수있는 Outlook을 복구 땀을 흘리지 않고 데이터.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 수리 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM