포함 된 모든 이미지를 Outlook 이메일의 첨부 파일로 빠르게 변환하는 방법

Outlook 솔루션 2025 년 9 월 29 일

메시지 본문에 포함 된 모든 그림을 이메일 첨부 파일로 빠르게 변경하려는 경우 수동으로 제거하고 다시 첨부 할 필요가 없습니다. 이 기사에서 공개 된 VBA 코드를 사용할 수 있습니다.

때로는 포함 된 모든 이미지를 첨부 파일로 일괄 변환 할 수 있습니다. 예를 들어 메시지 본문에 그림이 너무 많으면 본문의 텍스트를 읽는 데 방해가됩니다. 따라서 이메일 본문에서 제거하고 대신 첨부 파일로 추가하려고합니다. 물론 수동으로이 작업을 수행 할 수 있습니다. 그러나 도구 나 VBA 코드가 한 번에이를 얻을 수 있다면 더 편리해야합니다. 여기에서 그러한 VBA 코드를 공개합니다.

모든 포함 된 이미지를 첨부 파일로 빠르게 변환

우선, start Outlook 프로그램.
그런 다음 "개발자"탭으로 전환하고 "Visual Basic"버튼을 누를 수 있습니다.
다음으로 Outlook VBA 편집기 창으로 이동합니다.
이후에 다음 VBA 코드를 빈 모듈에 복사해야합니다.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

그런 다음 Outlook이 매크로를 허용하도록 설정되어 있는지 확인해야합니다.
선택적으로이 기능이 자주 필요한 경우 나중에 편리한 확인을 위해 새 매크로를 빠른 실행 도구 모음에 추가하는 것이 좋습니다.
결국 시도해 볼 수 있습니다. 이메일을 선택하거나 연 다음 빠른 실행 도구 모음에서 새 매크로 버튼을 클릭하여 매크로를 실행합니다.
즉시 모든 포함 된 이미지가 다음 스크린 샷과 같이 첨부 파일로 변경됩니다.

귀중한 Outlook 데이터를 보호하는 요령

우리 모두 알고 있듯이 Outlook PST 파일은 Word 문서 또는 Excel 스프레드 시트와 같은 일반적인 파일과 동일하게 취약합니다. 따라서 바이러스 또는 부적절한 처리와 같은 PST 파일과 관련된 모든 위험을 계속주의해야합니다. 따라서 PST 파일에 대한 정기적 인 데이터 백업을 만들어야합니다. 또한 감당할 수 있다면 견고하게 유지하는 것이 현명합니다. Outlook 수리 편리한 도구 DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM